Replace values in a list based on conditions

Question

I have a list with negative and positive numbers

list = {-1, -2, 1, 2}

and I want to replace all negative values with 0 and all positive values with 1 simultaneously. I only managed to replace one value at a time and don't know how to add a second condition. I did the following

list /. x_ /; x<0->1

I want something like:

 list /. x_ /; {x<0->0 && x>0->1}

but this does not work. So how to add a second condition?

ubpdqn · Accepted Answer · 2015-07-05T01:29:49.227

9

There a number of approaches. The desired behaviour of zero has not been specified.

Examples:

UnitStep[list]
Boole[# > 0] & /@ list
list /. {x_?Negative -> 0, x_?Positive -> 1}
HeavisideTheta[list]
(Unitize@# + Sign@#)/2 &@list

UnitStep[0] yields 1

The Boole approach will also yield zero but could be modified as desired.

The replacement rules has not specified zero so will leave it unchanged.

HeavisideTheta[0] yields HeavisideTheta[0]

The Unitize,Sign will yield 0.

There are other approaches.

edited Jul 05 '15 at 01:29

answered Jul 04 '15 at 09:57

ubpdqn

60,617
3
59
148

list/. {x_?Negative -> 0, x_?Positive -> 1} worked for me. I don't understand why list /. {x_<0 -> 0, x_>0 -> 1}, does not work, I did not know ?Negatvie and ?Positive before. – holistic Jul 04 '15 at 10:04
1

You can use list /. {x_ /; x < 0 -> 0, x_ /; x > 0 -> 1}, see the documentation on Condition. – Fred Simons Jul 04 '15 at 10:32
1

I believe UnitStep[0] results in 1. I like the solution Sign[list] rather than Boole[#.0] & /@ list. I prefer using built-in functions whenever they work. From a learning perspective the functional approaches are good. – Jack LaVigne Jul 04 '15 at 15:35
@JackLaVigne yes you are correct...apologies I will correct;) – ubpdqn Jul 05 '15 at 01:29
2

…Boole[Thread[list > 0]] will work nicely. – J. M.'s missing motivation Jul 05 '15 at 02:40
@J. M. very nice...always learn something...:) will leave as comment unless you think I should append with attribution of course :) – ubpdqn Jul 05 '15 at 02:42
It's entirely your call. I just shared what I do in these situations. :) – J. M.'s missing motivation Jul 05 '15 at 02:44

ciao · Answer 2 · 2015-07-05T07:15:22.990

5

These s/b considerably faster on large lists than solutions posted so far:

For integer lists:

UnitStep[Subtract[list, 1]]

For real lists:

 UnitStep[Subtract[Sign@list, 1]]

And I'd venture this will be quickest:

Clip[list, {0, 0}, {0, 1}]

edited Jul 05 '15 at 07:15

answered Jul 05 '15 at 07:09

ciao

25,774
2
58
139

(rasher) the first two are essentially correction to map 0 to 0 (noting the dealing with zero was not specified in OP)...Clip very nice :) – ubpdqn Jul 05 '15 at 07:22

score 1 · Answer 3 · answered Jul 05 '15 at 06:33

1

list = {-1, -2, 1, 2, 0} 
Floor[(1 + Sign[#])/2]&/@list

Note that 0 is replaced by 0.

If you prefer to replace 0 by 1, you must use:

Ceiling[(1 + Sign[#])/2]&/@list

answered Jul 05 '15 at 06:33

Enrique Pérez Herrero

982
1
9
14

Replace values in a list based on conditions

3 Answers3

Linked