Reduction of an Inequality in $\mathbb{C}$

Question

Reduce[
  Abs[-((4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] +
  Abs[-((4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] < 1 , Abs[p]]

It is taking lot of time. It is running. Can any one help to reduce the inequality?

Answer 1

Because the question seeks an expression for the modulus of p, it makes sense to express p and q in terms of the moduli and phases.

sim = Simplify[(Abs[-((4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] + 
                Abs[-((4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2)]) /. 
          {p -> pm Exp[I pp], q -> qm Exp[I qp]}, pm >= 0 && qm >= 0 && (pp | qp) ∈ Reals]
(* (4 (pm + qm))/Abs[-1 + Sqrt[1 + 4 E^(I pp) pm + 4 E^(I qp) qm]]^2 *)

In what follows, we explore sim <= 1 instead of the question's sim < 1 in order to obtain solutions at the boundary, sim == 1, which is where most solutions seem to lie. Although

Reduce[sim <= 1 && pm >= 0 && qm >= 0, pm]

still produced no answer, even after 19 hours, the special case of setting qp to π did. Some hand-holding was required, however.

Reduce[(sim /. {qp -> Pi}) <= 1 && 2 π > pp >= 0 && pm >= 0 && qm >= 0, pm]

returned unevaluated with the message

Reduce::nsmet: This system cannot be solved with the methods available to Reduce. >>

However,

Reduce[FullSimplify[Reduce[(sim /. {qp -> Pi}) <= 1 && pm >= 0 && qm >= 0, pm], 
    2 Pi > pp >= 0 && pm >= 0 && qm >= 0] && 2 Pi > pp >= 0 && pm >= 0 && qm >= 0, pm]

did produce a meaningful answer.

(* (0 <= pp < 2 π && qm >= 1/4 && pm == 0) || (pp == π && qm >= 1/4 && pm >= 0) || 
   (pp == π && ((qm > 1/4 && pm >= 0) || (0 <= qm <= 1/4 && pm >= 1/4 (1 - 4 qm)))) *)

Note that, except for the solution pm == 0, all these solutions require pp == π.

In summary, solutions are available for qp -> π and perhaps other cases. Whether a solution can be obtained in general within several hours of computation is unknown.

Answer 2

Using Mathematica as a tool for investigation suggests that no solution exists for $\text{"your expression"}<1$. If this is true, one would expect Reduce to return {}, albeit after a long time.

Here is a randomized exploration of 1,000,000 pairs of complex numbers with real and imaginary parts between -1000 and 1000:

f[{p_, q_}] := 
   Abs[-((4 p)/(-1 + Sqrt[1 + 4 p + 4 q])^2)] + 
   Abs[-((4 q)/(-1 + Sqrt[1 + 4 p + 4 q])^2)];
sample = With[{n = 1000000, a = 1000},
   RandomComplex[{-a - a I, a + a I}, {n, 2}]];
data = f /@ sample;
Min[data]
Histogram[ Log@data]

Answer 3

You want to find solutions to the strict inequality $$ \left| \frac{-4 p}{\left(\sqrt{4 p+4 q+1}-1\right)^2}\right| + \left| \frac{-4 q}{\left(\sqrt{4 p+4 q+1}-1\right)^2}\right| <1. $$ You can simplify a bit by replacing $4p$ and $4q$ by $p$ and $q$ and removing negative signs inside Abs: $$ \left| \frac{p}{\left(\sqrt{p+q+1}-1\right)^2}\right| + \left| \frac{q}{\left(\sqrt{p+q+1}-1\right)^2}\right|= \frac{|p|+|q|}{\left|\sqrt{p+q+1}-1\right|^2}<1 $$ which is equivalent to \begin{align} |p|+|q| &< |\sqrt{p+q+1}-1|^2\\ &=(\sqrt{p+q+1}-1)\overline{(\sqrt{p+q+1}-1)}\\ &=(\sqrt{p+q+1}-1)(\overline{\sqrt{p+q+1}}-1). \end{align} First consider the case where $p+q+1\in \mathbb C\setminus \mathbb R_-$, then we can replace the last factor by $$ \overline{\sqrt{p+q+1}}-1 ={\sqrt{\overline {p+q+1}}}-1 ={\sqrt{\overline p+\overline q+1}}-1. $$ In this case, we ask

Reduce[
  Abs[p] + Abs[q] 
  < (Sqrt[p + q + 1] - 1) ( Sqrt[p\[Conjugate] + q\[Conjugate] + 1] - 1), 
  {p, q}]
(* False *)

If on the other hand $p+q+1\in \mathbb R_-$ then:

Reduce[Abs[p] + Abs[q] < (Sqrt[r] - 1)^2 
  && p + q + 1 == r && r <= 0 && r \[Element] Reals, {p, q, r}]
(* False *)

and we can conclude that there are no solutions.

Non-strict version

Following the same line we look at two cases:

Reduce[Abs[p] + Abs[q] <=  
(Sqrt[p + q + 1] - 1)(Sqrt[p\[Conjugate] + q\[Conjugate] + 1] - 1), {p, q}]
(* 
 (-1 < p < 0 && q == -1 - p) || 
 (p == -1 && q == 0) || (p == 0 && (q == -1 || q == 0)) 
*)

and

Reduce[Abs[p] + Abs[q] <= (Sqrt[r] - 1)^2 
   && p + q + 1 == r && r <= 0 && r \[Element] Reals, {p, q, r}]
(*
((-1 < p < 0 && q == -1 - p) || (p == -1 && q == 0) || 
  (p == 0 && q == -1)) && r == 1 + p + q
*)