Take screenshot of the entire desktop using Mathematica

Question

Is it possible to get a screenshot of the entire desktop directly in Mathematica?

I am on Ubuntu running Mathematica 8. For some reason GUIScreenShot[] fails. But something like GUIScreenShot[{{0, 500}, {0, 500}}] works

It is strange that in the reference

GUIScreenShot[]

is given as an example (last one), with the caption Capture the entire screen:. But when I copy it and paste it in a notebook, it expects a parameter! (I have included the code Needs["GUIKit`"])

I get the error as shown in this image

Screenshot of the image

I am trying to automate a simple game (!). So grabbing it using an external program, then saving it as a file and importing the file again from within Mathematica is a tedious job (if not realtime). Also I am not sure if I can pipe the output of a program as input to Mathematica (I could not find a way to get it done with Run[] command! - i.e. the piping large output from external program) — my account_ram, Aug 11 '12 at 23:16
GUIScreenShot[] doesn't work for me (Arch Linux), it spits this error message on the terminal. Looks like a Linux issue... — Renan, Aug 12 '12 at 00:14
It works fine on my win7_x64 and mma8.0.4 (although a syntax indicator). Didn't know this function before. Very helpful! Thanks and +1! — Silvia, Aug 12 '12 at 06:52

score 16 · Answer 1 · answered Aug 11 '12 at 23:34

16

GUIScreenShot[] (without arguments) works perfectly fine on my Mac, although the front end syntax highlighter indicates a missing argument. As a workaround, you can explicitly give it the dimensions of your screen so that all of it is captured. Here's how you can programmatically get your screen size and use it:

Needs["GUIKit`"]
GUIScreenShot["FullScreenArea" /. Flatten@SystemInformation["Devices", "ScreenInformation"]]

answered Aug 11 '12 at 23:34

rm -rf

88,781
21
293
472

1

This does not seem to work on Ubuntu .. Can any1 confirm this ... – my account_ram Aug 12 '12 at 00:58
@myaccount_ram I'm having the same problem, but with Arch Linux. – Renan Aug 12 '12 at 04:00
@myaccount_ram It doesn't work on Fedora. – b.gates.you.know.what Aug 12 '12 at 07:34
I got ** Raster data contains 0 values per pixel; 3 or 4 are required with ColorFunction->RGBColor** under Linux 64. – Fred Daniel Kline Aug 12 '12 at 20:39
1

@everyone: The issue seems to be something related to linux and not Mathematica. I would've helped if I could, but I don't have a license to use on my Linux machine. – rm -rf Aug 13 '12 at 01:53
So many uses. Look: Needs["GUIKit`"] Dynamic[out] FixedPoint[(Pause[1]; out = GUIScreenShot[]) &, 0] – amr May 06 '13 at 01:15

score 8 · Answer 2 · answered Nov 07 '17 at 19:11

8

In v11.2 you can just use CurrentScreenImage[].

answered Nov 07 '17 at 19:11

user5601

3,573
2
24
56

score 7 · Answer 3 · edited Apr 13 '17 at 12:56

A method from Kuba's answer, no GUIKit` is needed. Tested on Mathematica 10.1.

Module[{masknb, img},
       masknb = CreateWindow[{}, WindowSize -> Full, Visible -> False];
       img = MathLink`CallFrontEnd[FrontEnd`NotebookImage[masknb]];
       NotebookClose[masknb];
       img
      ]

We can even make a fairly fast screen recorder from it:

Clear[maskWindow]
maskWindow[width_, height_, leftMarg_, topMarg_] :=
    CreateWindow[{},
        WindowSize -> {width, height},
        WindowMargins -> {{leftMarg, Automatic}, {topMarg, 0}},
        Visible -> False]

Clear[screenSnapshot]
screenSnapshot[window_] := 
    MathLink`CallFrontEnd[FrontEnd`NotebookImage[window]]

screenRecord = {};
recordingFlag = True;
Column[{
        "Click to stop recording:",
        Toggler[Dynamic[recordingFlag],
            {True -> Framed["Recording"], False -> Framed["Stopped  "]}
            ]
        }]

Module[{masknb},
        masknb = maskWindow[500, 300, 300, 200];
        While[recordingFlag,
            screenRecord = Join[screenRecord, {screenSnapshot[masknb]}]
            ];
        NotebookClose[masknb];
        ];
screenRecord = Image /@ screenRecord;
ListAnimate[screenRecord]

MMA screen recorder

Extremely Fast!!!!! Very impressive answer~ xie xie la~ but still, are there faster methods? — Wjx, Aug 25 '16 at 14:25
@Wjx Thanks! For better performance, I'd go win API + NETLink. — Silvia, Aug 26 '16 at 08:51

score 5 · Answer 4 · edited Aug 12 '12 at 11:57

5

Confirming @R.M's answer (WinXP, Mac OSX 10.8)

enter image description here

edited Aug 12 '12 at 11:57

rm -rf

88,781
21
293
472

answered Aug 11 '12 at 23:39

Dr. belisarius

115,881
13
203
453

1

why not a comment? Also, why are you hiding your porn tabs? ;) – rm -rf Aug 11 '12 at 23:44
@rm -rf The porn tabs are there ... look again – Dr. belisarius Aug 11 '12 at 23:45
@rm -rf Re: Why not a comment. I like the conceptual Droste Effect produced by the image of a question asking for a screen cap on the answer's screen cap. – Dr. belisarius Aug 11 '12 at 23:59
Doesn't work properly with more than one monitor. It only captures the primary monitor even if the MMA windows are on the other screen(s). – s0rce Aug 12 '12 at 03:28
1

@belisarius Nest[GUIScreenShot[], "", 10] – s0rce Aug 12 '12 at 03:29
1

@belisarius It's not a Droste effect until it is. – rm -rf Aug 12 '12 at 11:57
1

The Droste Effect: Dynamic[Export["C:\\droste.png", GUIScreenShot[]]; Style[GUIScreenShot[], Magnification -> 1], UpdateInterval -> 3]. When the Dynamic object is not visible, it is not updated (it is sufficient just to reduce the Mathematica window). – Alexey Popkov Aug 12 '12 at 18:33

partida · Answer 5 · 2017-01-21T15:57:08.377

Using JLink,you can do this

Needs["JLink`"];
InstallJava[];
robotclass = JavaNew["java.awt.Robot"];
LoadJavaClass["javax.imageio.ImageIO"];
LoadJavaClass["java.awt.Toolkit"];
screenSize = Toolkit`getDefaultToolkit[]@getScreenSize[];
image = robotclass@createScreenCapture[JavaNew["java.awt.Rectangle", 0, 0, screenSize@width, screenSize@height]];
ImageIO`write[image, "png",JavaNew["java.io.File", FileNameJoin[{Directory[], "test.png"}]]];
UninstallJava[]

Import["test.png"]

Take screenshot of the entire desktop using Mathematica

5 Answers5

Linked