How to find period of a discrete sequence?

Question

For example,

{1,2,3,4,5,6,7,8}

has period 1, the base is {1}

{1,2,4,5,7,8,10,11}

has period 3, the base is {1,2}

I notice there is a built-in function FunctionPeriod, but it doesn't work. eg

l[n_]:={1,2,4,5,7,8,10,11}[[n]]
FunctionPeriod[l[n],n,Integers]

So how to write a function period to find the period of discrete sequence.

ps: The sequence could be non-integers, for example sqrt, reals,

The sequences you show are not periodic at all. But if you apply Differences to them, you do get a periodic sequence. — Szabolcs, Oct 27 '15 at 15:06
I think you are using "period" in a different sense from what I'm accustomed to. To use some examples, $1,2,1,2,\dots$ is a $2$-periodic sequence, and $3,3,\dots$ is $1$-periodic. — J. M.'s missing motivation, Oct 27 '15 at 15:14
@J.M. Yeah, the "period" is in the sense of crystallography. The crystal structure is periodic. We talk about base and primitive translation vector in condensed matter physics. {1,2,4,5,7,8,10,11} could be viewed as the coordinates of atoms in 1d crystal — matheorem, Oct 27 '15 at 15:20
In that case: FunctionPeriod[FindSequenceFunction[Differences[{1, 2, 4, 5, 7, 8, 10, 11}], k], k]. — J. M.'s missing motivation, Oct 27 '15 at 15:22
@J.M. The result should be 3. Because translate {1,2} by 3 we got {4,5} — matheorem, Oct 27 '15 at 15:25
@J.M. Enlightened by you and Szabolcs. I figure out this works period[list_] := (list[[# + 1]] - list[[1]]) &@ Length[Tally[Differences[list]]]. period[{1, 2, 4, 5, 7, 8, 10, 11}] gives 3 — matheorem, Oct 27 '15 at 15:47
Might I suggest answering your own question, if you think you've figured it out? :) — J. M.'s missing motivation, Oct 27 '15 at 15:48
Modulo the already noted issue of taking successive differences, there is this prior related post. — Daniel Lichtblau, Oct 27 '15 at 20:44
@J.M. Thank you for giving me the opportunity. I answered my own question. I won't forget this was enlightened by you and Szabolcs :) — matheorem, Oct 28 '15 at 01:04
@DanielLichtblau Oh, thank you for reminding this. I should add that I want the minimal period. — matheorem, Oct 28 '15 at 01:05
@J.M. I found a bug in my code. Tally will not work for {1,1,3,1,1,3,1,1,3}. In my previous post quite related to this one http://mathematica.stackexchange.com/a/69128/4742 , bill suggest me to use "FindLinearRecurrence`. It works, but I don't understand this function, does it always give the right period? — matheorem, Oct 28 '15 at 01:55
@J.M. I understand FindLinearRecurrence. I should use this. I have modified my answer. — matheorem, Oct 28 '15 at 06:30
@Kuba the search function of stack exchange should be blamed :) I didn't find this post before. Thank you for providing the link — matheorem, Oct 28 '15 at 08:12

matheorem · Answer 1 · 2015-10-28T07:26:17.010

Let

list={1, 2, 4, 5, 7, 8, 10, 11}

then Differences[list] transform is list to periodic form

{1, 2, 1, 2, 1, 2, 1}

Length@FindLinearRecurrence@Rationalize@Differences[list] gives the periodicity is 2

Rationalize is necessary for real number list

But we want the translation period, so we can make the following

list[[2+1]]-list[[1]]

this gives the result 3

So the function that serves this purpose can be defined as

Clear[discreteperiod];
discreteperiod[list_] := Module[
  {recurrence = FindLinearRecurrence@Rationalize@Differences@list},
  If[Head[recurrence] === FindLinearRecurrence, 
   Print["The period contained in the list is not enough"]; 
   Abort[], (list[[# + 1]] - list[[1]]) &@Length[recurrence]]]

How to find period of a discrete sequence?

1 Answers1