Expanding out multiplied terms

Question

Is there any command in Mathematica to expand terms like $x^2\, y^3$ to $x\,x\,y\,y\,y$?

I tried PowerExpansion, but it works for expressions like $(x\,y)^2$ which gives $x^2\,y^2$.

You could write a routine yourself using Row[] and ConstantArray[]… — J. M.'s missing motivation, Nov 01 '15 at 10:16

score 10 · Accepted Answer · answered Nov 01 '15 at 13:42

10

This is a task for Inactivate/Inactive and HoldForm:

powerProductForm[expr_] :=
 With[{expanded = Inactivate[
      expr /. Power[u_, n_Integer?Positive] :>
        Inactive[Times] @@ ConstantArray[u, n],
      Times
      ] /.
     prod : Inactive[Times][__] :> Flatten[prod]},
  Activate@HoldForm[expanded]];

Then

In[2]:= powerProductForm[x^2*y^3 + x*y^2 + 2*z^3*w^4]
Out[2]= x y y + x x y y y + 2 w w w w z z z

answered Nov 01 '15 at 13:42

Pillsy

18,498
2
46
92

2

I'd use Defer[] instead of HoldForm[] myself... – J. M.'s missing motivation Nov 01 '15 at 13:59
Unfortunately I can't get your output. It gives Activate[Inactivate blah blah blah!! – MEDVIS Nov 02 '15 at 06:16
@MEDVIS What version of Mathematica are you using? Inactivate was introduced in 10.0. – Pillsy Nov 02 '15 at 13:05
@Pillsy So that's the reason... I'm using version 9. I'll try it with another computer – MEDVIS Nov 02 '15 at 14:05

score 8 · Answer 2 · answered Nov 01 '15 at 10:38

8

J. M. beat me to it with the comment, but here's some example code:

f=(x^2 y^3);

Row@
  Flatten@
    (ConstantArray @@@
      Cases[#, Power[b_, e_] :> {b, e}] &@
    f)

You should think about whether you need the expansion purely for display purposes though, or whether you need to do any further manipulation. xxyyy in the above example is something complete different to Mathematica than x^2 y^3.

answered Nov 01 '15 at 10:38

Graumagier

1,130
5
11

3

In a similar vein: With[{prod = Join @@ (x^2 y^3 /. {Times -> List, Power -> ConstantArray})}, Defer[prod] /. List -> Times]. – J. M.'s missing motivation Nov 01 '15 at 11:38
I actually prefer you solution because you can plug it right back in and recover the original form. – Graumagier Nov 01 '15 at 11:41
"you can plug it right back in and recover the original form." - that was the intention, yes. :) – J. M.'s missing motivation Nov 01 '15 at 11:52
I guessed so, I just wanted to make it more explicit ;) – Graumagier Nov 01 '15 at 11:55

score 5 · Answer 3 · answered Nov 01 '15 at 11:19

If this is for display purposes you could use Format:

Format[fmt[{x_, n_}], TraditionalForm] := Row@Table[x, {n}]
fmt[{x_, 0}] := 1
fun[poly_, {var__}] := With[{cr = CoefficientRules[poly, {var}]},
  Times @@ MapThread[fmt[{#2, #1}] &, {#, {var}}] & /@ 
     cr[[All, 1]].cr[[All, 2]] // TraditionalForm
  ]

For example:

fun[3 x^2 z^6 + x^2 y^3 + z^5 x y^4 + 4 x y z, {x, y, z}]

yields:

Expanding out multiplied terms

3 Answers3

Linked

Related