Displaying on a Smartboard

Question

I got a very nice answer on Region bounded by x^2+y^2=1, y=z, x=0, z=0, in first octant, using this code:

Plot3D[y, {x, 0, 1}, {y, 0, 1},
 RegionFunction ->
  Function[{x, y, z},
   x^2 + y^2 <= 1 && x >= 0 && y >= 0 && z >= 0],
 Filling -> 0,
 FillingStyle -> Opacity[.75],
 PlotStyle -> Opacity[.5],
 AxesLabel -> (Style[#, 14, Bold] & /@ {x, y, z}),
 BoxRatios -> {1, 1, 1},
 ViewPoint -> {3, -1.5, 0.75}]

Which produces this image:

Bob Hanlon also provided a very nice Manipulate idea to explore the use of PlotThemes.

However, I'd still like to find out if there are folks on Mathematica Stack Exchange that use a Smartboard to present Mathematica images when teaching class, and if so, can you make the best recommendation for color effects (which I know little about) that produce an image on the Smartboard that is best visualized by the students in the room. I find the default colors to be too dark when viewing on the Smartboard. Do you have a favorite set of colors that work best when presenting an image on a Smartboard?

Hi, David, I have no experience with the smartboard, and cannot give an advice, but it seems reasonable to first play with the value of Opacityoption. If you put it 0.7 or even 0.8 the image will be still transparent, but the colors will be better visible. Second, I would play with different ColorSchemesand see how do they perform on the smartboard, (see the continuation) — Alexei Boulbitch, Nov 03 '15 at 10:17
(Continuation) Like this, for example, like here: Plot3D[y, {x, 0, 1}, {y, 0, 1}, RegionFunction -> Function[{x, y, z}, x^2 + y^2 <= 1 && x >= 0 && y >= 0 && z >= 0], Filling -> 0, FillingStyle -> Opacity[.75], PlotStyle -> Opacity[.8], AxesLabel -> (Style[#, 14, Bold] & /@ {x, y, z}), BoxRatios -> {1, 1, 1}, ViewPoint -> {3, -1.5, 0.75}, ColorFunction -> #] & /@ ColorData["Gradients"]. You might also use other color schemes. See the continuation — Alexei Boulbitch, Nov 03 '15 at 10:25
Continuation 2: Then, Lighting might also help, like here: Plot3D[y, {x, 0, 1}, {y, 0, 1}, RegionFunction -> Function[{x, y, z}, x^2 + y^2 <= 1 && x >= 0 && y >= 0 && z >= 0], Filling -> 0, FillingStyle -> Opacity[.75], PlotStyle -> Opacity[.8], AxesLabel -> (Style[#, 14, Bold] & /@ {x, y, z}), BoxRatios -> {1, 1, 1}, ViewPoint -> {3, -1.5, 0.75}, ColorFunction -> "TemperatureMap", Mesh -> None, Lighting -> #] & /@ {Automatic, {{"Ambient", Red}}}. But you need just to try. Have fun! — Alexei Boulbitch, Nov 03 '15 at 10:27

score 2 · Accepted Answer · answered Nov 03 '15 at 15:01

You might try experimenting with the colors. Below I change the values of given to FillingStyle and PlotStyle. This lightens things up quite a bit and, perhaps, more to your liking.

With[{style = {Opacity[.75], Glow[Yellow]}}, 
  Plot3D[y, {x, 0, 1}, {y, 0, 1}, 
    RegionFunction -> 
      Function[{x, y, z}, x^2 + y^2 <= 1 && x >= 0 && y >= 0 && z >= 0],
    Filling -> 0,
    FillingStyle -> style,
    PlotStyle -> style,
    AxesLabel -> (Style[#, 14, Bold] & /@ {x, y, z}),
    BoxRatios -> {1, 1, 1},
    ViewPoint -> {3, -1.5, 0.75}]]

I am going to find this extremely useful. Thank you so much. — David, Jun 01 '16 at 04:27

Displaying on a Smartboard

1 Answers1