Interval calculations in wolfram mathematica

Question

If x = Interval[{-100,100}], then obviously x^2 + x = Interval[{-1/4,10100}], because as we know, x^2+x > -1/4. But Mathematica gives me:

x^2 + x /. x -> Interval[{-100, 100}]
(* Interval[{-100, 10100}] *)

How can I automatically get correct interval Interval[-1/4,10100] from Mathematica?

ref / Interval / Possible Issues – Kuba Nov 03 '15 at 14:08 — Kuba, Nov 03 '15 at 14:08

score 8 · Answer 1 · answered Nov 03 '15 at 14:32

8

A possible approach for dependent intervals:

Interval@*Through@{MinValue, MaxValue}[u + u^2, {u} ∈ Interval[{-100, 100}]]
(* Interval[{-(1/4), 10100}] *)

answered Nov 03 '15 at 14:32

ybeltukov

43,673
5
108
212

1

That's a new one, what does @* mean? – Jason B. Nov 03 '15 at 14:35
4

Is it really impossible to make this searchable in the documentation? Typing ?@@ works, but ?@@@ or ?@ or ?@* gives nothing – Jason B. Nov 03 '15 at 14:38
I'd be very thankfull if author will explain this strange syntax with @* – stiv Nov 03 '15 at 14:52
1

It's Composition, as in Composition[f, g, h][x] means f[g[h[x]]]. What I don't understand is why it is needed - f @ g @ h @ x seems to give the same answer as f @* g @* h @ x – Jason B. Nov 03 '15 at 14:58
@JasonB What the @#%^&*?! do all those funny signs mean? -- There's no need here for @*, but @* is useful, for example, in Map. – Michael E2 Nov 03 '15 at 15:47
That post is very useful, but I still think Wolfram should do something to make them more searchable in their documentation. – Jason B. Nov 03 '15 at 16:06
2

@JasonB Actually ? and @ acts weird together. Sometimes @ is any number of lowercase characters and sometimes not. – ybeltukov Nov 03 '15 at 16:34
@Jason, that shorthand is quite new (haven't gotten used to it myself); I guess they haven't documented it that well just yet. – J. M.'s missing motivation Nov 03 '15 at 17:23

score 5 · Answer 2 · answered Nov 03 '15 at 14:16

5

u = Interval[{-100, 100}]

According to ref / Interval / Possible Issues

Intervals are always assumed independent

so u + u^2 is something like v + u ^ 2 -> Interval[{-100, 100}] + Interval[{0, 10000}].

What can also be surprising, is the fact it is different from u + u * u which we can think of as v + u * w.

I the first example u^2 is at least 0 but in the second u can be -100 while w is 100 so the answer is: Interval[{-100, 100}] + Interval[{-10000, 10000}] -> Interval[{-10100, 10000}]

answered Nov 03 '15 at 14:16

Kuba

136,707
13
279
740

How can I automatically get correct interval Interval[-0.25,10100] from Mathematica? – stiv Nov 03 '15 at 14:27
@stiv good point, I should answer the question :) – Kuba Nov 03 '15 at 14:33

Eric Towers · Accepted Answer · 2015-11-05T20:18:45.580

A different way to go that captures more information than merely the intervals is:

result = TransformedDistribution[x^2 + x, Distributed[x, UniformDistribution[{-100, 100}]] ];
Plot[Evaluate[PDF[result, x]], {x, -1, 1}]
(* Discover that the likelihood of various results is not uniform. *)
Interval[{
  Minimize[{x, #}, x, Reals][[1]],
  Maximize[{x, #}, x, Reals][[1]]
} &[Reduce[PDF[result, x] > 0, x]]]

We can wrap this in a function (includes streamlining from @ybeltukov ):

dependentInterval[func_, marginVar_, varDef___] := Interval[{
  MinValue[{marginVar, #}, marginVar, Reals],
  MaxValue[{marginVar, #}, marginVar, Reals]
} &[Reduce[
  PDF[TransformedDistribution[func, Sequence /@ varDef], 
  marginVar] > 0, marginVar]
]]

dependentInterval[x^2 + x, x, Distributed[x, UniformDistribution[{-100, 100}]] ]
(* Interval[{-(1/4), 10100}] *)

@ybeltukov : You're right. (Ack. How did this post make it to the top answer?...) — Eric Towers, Nov 05 '15 at 20:12

Carl Woll · Answer 4 · 2021-10-07T22:53:03.570

You can use FunctionRange. For example:

IntervalReplace[expr_, x_ -> int_Interval] := Module[{f},
    f = Quiet[
        Check[
            FunctionRange[{expr,{x}\[Element]int},x,y],
            Message[IntervalRange::nmet];
            $Failed,
            FunctionRange::nmet
        ],
        FunctionRange::nmet
    ];
    ToInterval[f, y] /; f =!= $Failed
]
IntervalRange::nmet = FunctionRange::nmet;

Then:

IntervalReplace[x^2 + x, x -> Interval[{-100, 100}]]

Interval[{-(1/4), 10100}]

More complicated examples:

IntervalReplace[1/x + x, x -> Interval[{-100, 100}]]

Interval[{-\[Infinity], -2}, {2, \[Infinity]}]

IntervalReplace[x^2+DawsonF[x], x -> Interval[{-11,11}]] //N

Interval[{-0.201125, 121.046}]

Interval calculations in wolfram mathematica

4 Answers4

Linked

Related