It is necessary to construct a vector diagram when a known angle relative to the horizontal axis and the length of the vector

Question

Willing to construct a phasor diagram which consists of 2 vectors and one vector sum. An example is shown below.

Answer 1

This is straight forward in most of the TeX-friendly drawing tools.

Here for example is a Metapost example:

which was produced with this:

prologues := 3;
outputtemplate := "%j%c.eps";

beginfig(1);

u = 1cm;

path xx, yy;

xx = (left--5 right) scaled u;
yy = xx rotated 90;

draw xx withcolor .7 white;
draw yy withcolor .7 white;

z1 = (4u,u);
z2 = (u,2.828u);
z3 = z1 + z2;

draw z1--z3 withcolor .7 white;
draw z2--z3 withcolor .7 white;

drawarrow origin -- z1;
drawarrow origin -- z2;
drawarrow origin -- z3;

label.rt (btex $x$ etex, point 1 of xx);
label.top(btex $y$ etex, point 1 of yy);
dotlabel.llft(btex $0$ etex, origin);

endfig;
end.

If you want to specify the coordinates using polar notation, as implied by the title of your question, you can replace the lines defining z1 and z2 with something like this:

z1 = right scaled 4u rotated 17;
z2 = right scaled 3u rotated 60;

where 4u and 17° is the first length and rotation and 3u and 60° is the second.

I hope that helps.