Union of paths in asymptote

Question

I am trying to get the union of four circles in asymptote:

unitsize(1mm);
import graph;
pair o1 = (0, 0);
pair o2 = (10, 0);
pair o3 = (10, 10);
pair o4 = (0, 10);
path c1 = Circle(o1, 10);
path c2 = Circle(o2, 10);
path c3 = Circle(o3, 10);
path c4 = Circle(o4, 10);
draw(c1^^c2^^c3^^c4, black);

Apparently this is not the right way:

Using inkscape I can get the desired effect:

@g.kov 's answer partially solves the problem, but if the paths are not consecutively intersecting, then buildcycle will not work:

unitsize(1mm);
import graph;
pair o1 = (0, 0);
pair o2 = (10, 0);
pair o3 = (10, 10);
pair o4 = (0, 10);
path c1 = Circle(o1, 8);
path c2 = Circle(o2, 8);
path c3 = Circle(o3, 1);
path c4 = Circle(o4, 1);

guide[] gg=c1^^c2^^c3^^c4;
guide g=gg[0];
for(int i=1;i<gg.length;++i){
  g=buildcycle(g,gg[i]);
}

draw(g,black);

This outputs nothing, while what I wanted is this (output from inkscape):

The reason I am checking out asymptote is that it's a programming language and should be much more powerful when the number of paths increase to a higher order.

Answer 1

Consequent buildcycle commands can be used in this case:

unitsize(1mm);
import graph;
pair o1 = (0, 0);
pair o2 = (10, 0);
pair o3 = (10, 10);
pair o4 = (0, 10);
path c1 = Circle(o1, 10);
path c2 = Circle(o2, 10);
path c3 = Circle(o3, 10);
path c4 = Circle(o4, 10);

guide[] gg=c1^^c2^^c3^^c4;
guide g=gg[0];
for(int i=1;i<gg.length;++i){
  g=buildcycle(g,gg[i]);
}

filldraw(g,palegreen,deepblue);

Edit:

Well, the second case is a little more complicated than the original one. This modified code seems to work in this case:

unitsize(1mm);
import graph;
pair o1 = (0, 0);
pair o2 = (10, 0);
pair o3 = (10, 10);
pair o4 = (0, 10);

path c1 = Circle(o1, 8);
path c2 = Circle(o2, 8);
path c3 = Circle(o3, 1);
path c4 = Circle(o4, 1);

guide[] gg=c1^^c2^^c3^^c4;
int[] ind2del;
int j=0;
bool flag=true;
while(flag){
  flag=false;
  ind2del.delete();
  for(int i=j+1;i<gg.length;++i){
    if(intersect(gg[j],gg[i]).length>0){
      gg[j]=buildcycle(gg[j],gg[i]);
      ind2del.push(i);
      flag=true;
    }
  }
  for(int i=ind2del.length-1;i>=0;--i)gg.delete(ind2del[i]);
  ++j;
  if(j<gg.length){
    flag=true;
  }else{
    j=0;
  }
}

filldraw(gg,palegreen,deepblue);