Slice a mathematica image into sub images along black straight lines?

Question

I have a tic tac toe board I want to dynamically process in mathematica to have my robot play a user in tic tac toe. In order to determine the users move, I want to slice the board into 9 images, which are the 9 boxes of the board. How can I slice this image of the board into 9 boxes representing each space where there can be a move?

The image has white space and therefore using imagePartition produces something like:

This is because the boxes are not perfect squares, and the board is not perfectly in the center of the image.

Additionally, here is an example of the board that our delta robot draws:

How would I use that to slice directly along the lines thought? Additionally how do I store each image in an array of images? — Jenny, Jan 30 '16 at 17:42
Imagine a Tic Tac Toe board. I want to slice exactly along the lines so I can see what is in each position — Jenny, Jan 30 '16 at 17:45
So the board may not be perfect, we are processing it with a webcam — Jenny, Jan 30 '16 at 17:58
Another: How to detect crosses and circles in 60x60 raster images? — Oleksandr R., Jan 30 '16 at 18:14
Once I detect those grid lines however, how can I partition the image into segments to evaluate individually? — Jenny, Jan 30 '16 at 18:41

Dr. belisarius · Accepted Answer · 2016-01-30T20:31:33.647

5

Framed[i = Import["https://i.stack.imgur.com/tTeBU.png"]]

Mathematica graphics

ib = ColorNegate@Binarize@i;
sc = SelectComponents[ib, "Count", -1];
bb = ComponentMeasurements[sc, "BoundingBox"];
bs = Reverse[Sort /@ {#[[1]], Last@ImageDimensions@sc - #[[2]]} &@ Transpose[bb[[1, 2]]]];
it = ImageTake[sc, Sequence @@ bs];
it1 = ImageTake[i, Sequence @@ bs];
eps = MorphologicalTransform[Thinning@it, "EndPoints"];
nw = NestWhile[ImageTake[#, {2, -2}, {2, -2}] & /@ # &, {it1, it, eps}, 
   ComponentMeasurements[#[[3]], "Mask", "BorderComponents" -> False] =!= {} &];

Partition[Framed /@ (ImageMultiply[nw[[1]], #] & /@ (Erosion[#, 1] & /@ Image /@
              (ComponentMeasurements[ColorNegate@nw[[2]], "Mask"][[All, 2]]))), 3] //
              Grid

Mathematica graphics

edited Jan 30 '16 at 20:31

answered Jan 30 '16 at 20:02

Dr. belisarius

115,881
13
203
453

Why does mine return this? http://postimg.org/image/lain5m35t/ – Jenny Jan 30 '16 at 20:41
Additionally, why do the marks change locations from the original board? – Jenny Jan 30 '16 at 20:45
Probably because you forgot my first line – Dr. belisarius Jan 30 '16 at 20:46
These are the exact same commands copied and pasted: http://postimg.org/image/jxj8731p1/ – Jenny Jan 30 '16 at 20:48
Are you running Mathematica 10? – Jenny Jan 30 '16 at 21:36
Nope, Mathematica V9 here – Dr. belisarius Jan 30 '16 at 21:53
1

Do you know why the symbols change location in your example? – Jenny Jan 30 '16 at 21:59

score 4 · Answer 2 · answered Jan 31 '16 at 04:51

One way to approach this is to use a Watershed algorithm to segment the image. Each of the watersheds contains one of the symbols.

i = Import["https://i.stack.imgur.com/tTeBU.png"];
waterI = WatershedComponents[i];
waterI // Colorize

You can then separate out the three symbols

{m1, m2, m3, m4} = ComponentMeasurements[waterI, "Mask"];
{ImageMultiply[Image[Normal[m1[[2]]]], i], 
 ImageMultiply[Image[Normal[m3[[2]]]], i], 
 ImageMultiply[Image[Normal[m4[[2]]]], i]}

Slice a mathematica image into sub images along black straight lines?

2 Answers2