How can I plot the complex graph of $x^x$ in Mathematica?

Question

For example, this Wolfram Alpha query shows this graph:

enter image description here

But it does not show the code for plotting it in Mathematica. Plot[x^x, {x, -1, 1}] only plots the real values. How can I do this in Mathematica?

Try this:Plot[{Re[x^x], Im[x^x]}, {x, -1, 2}, PlotRange -> All] — xzczd, Sep 14 '12 at 04:39
...then there's also this... (one of the vagaries of having to choose a "principal branch" for the logarithm) — J. M.'s missing motivation, Sep 14 '12 at 05:18
Possible duplicates: http://mathematica.stackexchange.com/questions/3458/plotting-complex-quantity-functions and http://mathematica.stackexchange.com/questions/5754/how-to-plot-imaginary-part-of-a-function — Sjoerd C. de Vries, Sep 14 '12 at 05:56

Mark McClure · Answer 1 · 2014-08-07T19:55:30.710

Here's a view that shows how the graph starts to spiral for negative $x$ values, if we take the complex values into account.

ParametricPlot3D[{x, Re[Exp[x*Log[x]]], Im[Exp[x*Log[x]]]}, 
  {x, -4, 2}, PlotRange -> All, ViewVertical -> {0, 1, 0},
  BoxRatios -> {2, 1, 1}, ViewPoint -> {2, 2, 12}]

enter image description here

In fact, if we write $x^x = e^{x\log(x)}$, this naturally generallizes to $x^x = e^{x\log(x) + 2i\pi k}$; each $2i\pi k$ represents another branch of the complex logarithm. In this context, we see that this graph just forms one spiral of a family of spirals.

x2x[0.0, _] = x2x[0, _] = 1;
x2x[x_, k_] := Exp[x (Log[x] + 2 I Pi k)];
Table[points3D[k] = Table[
  z =  x2x[x, k];
  {x, Re[z], Im[z]},
  {x, -4, 2, 0.005}],
{k, -7, 7}];
Graphics3D[Table[{If[k == 0, Thick, Opacity[0.5]], 
  Line[points3D[k]]}, {k, -4, 4}],    
  Axes -> True, PlotRange -> {{-4, 2}, {-4, 4}, {-4, 4}}, 
  BoxRatios -> {2, 1, 1}, ViewPoint -> {2, 2, 12}, 
  ViewVertical -> {0, 1, 0}]

enter image description here

In elementary classes, you might see the claim that $(p/q)^{p/q}$ is defined for $p$ negative and $q$ odd and positive. Thus, including these points, the graph might look something like so:

points = Union[Cases[Table[Chop[points3D[k], 1/10], {k, -7, 7}], 
  {_?Negative, _, 0}, {2}]];
Plot[x^x, {x, 0, 2}, PlotStyle -> Directive[Thick, Black],
  Epilog -> Point[Most /@ points], PlotRange -> {{-2, 2}, {-2, 4}}]

enter image description here

From the complex perspective, the dots arise as spots where one of the spiral threads punctures the $x$-$z$ plane.

I chose yulinlinyu's as the answer because it answered my question directly and succinctly - but Mark Mcclure's answer goes above and beyond - and is the real jewel in this thread! — Faisal Vali, Sep 17 '12 at 18:17

score 18 · Answer 2 · edited Apr 13 '17 at 12:55

18

As yulinyu has pointed out, something like the following will give you the desired plot.

Plot[Through[{Re, Im}[x^x]], {x, -2, 2}, Evaluated -> True]

You might also be interested in this excellent answer by Simon Woods to create a graph of the plot over the complex domain. Using his function and evaluating the following gives you a pretty picture

domainPlot[#^# &]

enter image description here

edited Apr 13 '17 at 12:55

Community

1

answered Sep 14 '12 at 04:47

rm -rf

88,781
21
293
472

5

For a second I thought I smoked .... but no – Dr. belisarius Sep 14 '12 at 05:20
3

Are you training your hypno-powers? – Dr. belisarius Sep 14 '12 at 05:40

score 15 · Accepted Answer · edited Sep 14 '12 at 04:50

15

Plot[{Re[x^x], Im[x^x]}, {x, -1, 2}]

edited Sep 14 '12 at 04:50

J. M.'s missing motivation

124,525
11
401
574

answered Sep 14 '12 at 04:40

yulinlinyu

4,815
2
29
36

score 1 · Answer 4 · answered May 09 '19 at 05:11

1

You can use the new in M12 functions ReImPlot and ComplexPlot for complex visualizations of a function. Using ReImPlot:

ReImPlot[z^z, {z, -2, 2}]

and ComplexPlot:

ComplexPlot[z^z, {z, - 3 - 3 I, 3 + 3 I}]

answered May 09 '19 at 05:11

Carl Woll

130,679
6
243
355

score 0 · Answer 5 · edited Jun 16 '20 at 09:23

0

Also

ComplexPlot3D[z^z, {z, -3 - 3 I, 3 + 3 I}]

does the job in version 12.0.

edited Jun 16 '20 at 09:23

Community

1

answered May 09 '19 at 06:23

user64494

26,149
4
27
56

How can I plot the complex graph of $x^x$ in Mathematica?

5 Answers5

Linked