Successive Series Expansion Bug (?)

Question

I've found what appears to be a bug in MMA related to taking successive series expansions. I'm providing this minimal example and post as other posts didn't appear to address the issue I found.

In particular, MMA seems to get confused in keeping track of orders of parameters when future expansion parameters are in the powers of earlier expansion parameters, which seems to be due to a limitation of the SeriesData object that Series produces.

While it appears known that MMA may include extra powers, e.g. Multivariable Taylor expansion does not work as expected, in my example MMA misses some critical terms. For example

Series[x^z y^z (1 + x + y)/z, {x, 0, 0}, {y, 0, 0}, {z, 0, 1}] // Normal

yields the incorrect expression

$$ \frac{1}{z}+\log (x)+\log (y) + z \log (x) \log (y) $$

whereas

Series[Series[Series[x^z y^z (1 + x + y)/z, {x, 0, 0}] //
  Normal, {y, 0, 0}] //Normal, {z, 0, 1}] // Normal

captures all the correct terms,

$$ \frac{1}{z}+\log (x)+\log (y) + \frac{1}{2} z \big( \log ^2(x)+2 \log (x) \log (y)+\log ^2(y) \big). $$

It seems that the critical point is to ensure that one finds the correct answer, each Series[] result needs to be hit with a Normal[] first, before performing the next Series[].

Interestingly, the first method does not miss any terms when I remove the $1/z$ from the expression to be expanded and ask for a series expansion up to $O(z^2)$, although the first method does then give some extra terms $O(z^3)$ and $O(z^4)$, too.

Possibly the bug (?) described above is related to Peculiarities with Series and fractional exponents or bug?.

Answer 1

The order of evaluation business is confusing. It really does go from inside outward for Series. We can see this from the example under Generalizations and Extensions on the ref guide page.

Here is the example.

Series[Sin[x + y], {x, 0, 3}, {y, 0, 3}]

First we show the result of handling the variable x.

In[579]:= InputForm[Series[Sin[x + y], {x, 0, 3}]]
Out[579]//InputForm=
SeriesData[x, 0, {Sin[y], Cos[y], -Sin[y]/2, -Cos[y]/6}, 0, 4, 1]

The full result is basically the result of now going inside each series coefficient when handling the y terms.

In[576]:= InputForm[Series[Sin[x + y], {x, 0, 3}, {y, 0, 3}]]
Out[576]//InputForm=
SeriesData[x, 0, {SeriesData[y, 0, {1, 0, -1/6}, 1, 4, 1], 
  SeriesData[y, 0, {1, 0, -1/2}, 0, 4, 1], 
  SeriesData[y, 0, {-1/2, 0, 1/12}, 1, 4, 1], 
  SeriesData[y, 0, {-1/6, 0, 1/12}, 0, 4, 1]}, 0, 4, 1]

When we get to the example from this post, I'm not sure if what we see is a bug or a feature. The InputForm shows some levels of nesting of z that seem amiss. I'll take a closer look if I get a chance.

--- edit ---

It's a feature. Here is a simpler form of the input that elicits the same behavior. I'll show it in two separate steps.

In[1381]:= InputForm[s1 = Series[x^z (1 + x)/z, {x, 0, 0}]]
Out[1381]//InputForm=
x^z*SeriesData[x, 0, {z^(-1)}, 0, 1, 1]

Fine so far, all according to documented behavior. Now try to extract a series in z.

In[1382]:= InputForm[Series[s1, {z, 0, 1}]]
Out[1382]//InputForm=
SeriesData[z, 0, 
{SeriesData[x, 0, {SeriesData[z, 0, {1}, -1, 2, 1]}, 0, 1, 1],
SeriesData[x, 0,
 {SeriesData[z, 0, {Log[x]}, -1, 2, 1]}, 0, 1, 1]},  0, 2, 1]

We now have nested series in z. While not desirable, I don't see any clean way to circumvent this. The upshot is that, for a nested series, we can expect trouble when an outer series is presented something that has its variable both inside and outside of SeriesData objects.

As noted already in this thread, a viable way around this is to interpose Normal between nested series evaluations.

--- end edit ---