Intensity variation of image as ContourPlot

Question

I would like to color code the brightness values of an image (8bit, gray scale, 1600*1200 pixels). Each pixel should be color coded according to its brightness value using a dedicated color table.

An example image can be downloaded here.

The brightness histogram is:

Histogram[Flatten@ImageData@image, {1/256}, ScalingFunctions -> "Log",
  Frame -> True, FrameLabel -> {{"# of Pixels", ""}, {"Brightness", ""}}, 
  BaseStyle -> {FontWeight -> "Bold", FontSize -> 40, 
  FontFamily -> "Calibri"}, PlotRange -> {{0, 1}, All}, 
  ImageSize -> 2000, ImagePadding -> {{All, All}, {All, 50}}]

So most of the brightness values are around 0.045.

I tested ListContourPlot but it is extremely slow (AbsoluteTiming gives 91 sec).

colTable = {{Black}, 
   Table[{Blend[{Blue, Green, Yellow, Red}, x]}, {x, 0.2, 1, 0.1}]}; 
colTable = Flatten[colTable]

ListContourPlot[ImageData@image, PlotLegends -> Automatic, 
 ColorFunction -> (Blend[colTable, #] &), Contours -> 10]

How can I improve the contrast of the color coded image?

Do you know an other or faster solution?

@Young: The image in the link corresponds to the image in the code. — mrz, Jul 13 '16 at 14:05
@mrz - I don't get the same result when I run your code: http://i.stack.imgur.com/12N5E.png — Jason B., Jul 13 '16 at 14:26
But that last image looked more interesting - how did you get it? — Jason B., Jul 13 '16 at 19:44

score 1 · Accepted Answer · edited Apr 13 '17 at 12:56

1

Update

New and fast (4 seconds) way to achieve plot and scale.

colTable = {{Black}, Table[{Blend[{Blue, Green, Yellow, Red}, x]}, {x, 0.2, 1, 0.1}]};
colTable = Flatten[colTable];

ArrayPlot[ImageData[imageOrg], ColorFunction -> (Blend[colTable, #] &),
          PlotLegends -> Automatic, FrameTicks -> All]

Other methods:

Colorize

Colorize[imageOrg, ColorFunction -> (Blend[colTable, #] &),
         ColorFunctionScaling -> False] //Timing

2.15281

How do I apply a ColorDataFunction[] to a grayscale image?

Image@Raster[ImageData[imageOrg, DataReversed -> True],
             ColorFunction -> (Blend[colTable, #] &)] // Timing

2.19961

edited Apr 13 '17 at 12:56

Community

1

answered Jul 13 '16 at 13:54

Young

7,495
1
20
45

Thank you ... this is very fast, but if I use my color table the output of your code is different than my image above, why? Is it possible to use Colorize with a legend showing which color corresponds to which brightness? – mrz Jul 13 '16 at 14:03
@mrz I'm unable to replicate your histogram or plot even when I run your code – Young Jul 13 '16 at 14:42
Now it should work. When I use Image@Raster[ImageData[image, DataReversed -> True], ColorFunction -> (Blend[colTable, #] &)] I get a relatively nice image. – mrz Jul 13 '16 at 16:47
@mrz Seems just as fast – Young Jul 13 '16 at 19:18
Very good ... is there a way to plot beside the image a legend showing which color corresponds to which brightness? – mrz Jul 13 '16 at 19:42
@mrz found a new way that's fast and adds the scale easily – Young Jul 13 '16 at 21:25
2

You might be interested in this. – J. M.'s missing motivation Jul 14 '16 at 02:45
@J. M.: Your link is extremely helpful, I will try to adapt it to my question ... thank you – mrz Jul 14 '16 at 10:34

score 0 · Answer 2 · answered Jul 21 '16 at 04:22

Another color table:

colTable = 
 Flatten@{Table[Black, {x, 0, 12, 1}], 
   Table[{Blend[{Blue, Green, Yellow, Red}, x]}, {x, 1/10, 1, 1/10}], 
   Table[Black, {x, 24, 256, 1}]}

ArrayPlot[ImageData[image], ColorFunction -> (Blend[colTable, #] &), 
 PlotLegends -> Automatic, FrameTicks -> All]

Colorize[image, ColorFunction -> (Blend[colTable, #] &)]

Intensity variation of image as ContourPlot

2 Answers2