How can I completely remove the ListAnimate controls?

Question

I want to use ListAnimate to show an animation but I want to remove the slider and all of the buttons from the top and show the animation panel only. There is an AppearanceElements -> None option but it doesn't remove the slider and the other buttons. How can I remove all of the controls?

Just a note: ControlType->None will do this but there will be no animation but only a rasterized image. — Kuba, Apr 26 '14 at 09:56
Closely related: Is it possible to insert an animated image into Mathematica notebook? — Jens, Apr 26 '14 at 20:52

Vitaliy Kaurov · Accepted Answer · 2012-10-14T09:42:15.557

19

If you look at underlying code:

ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 25}]] // InputForm

at the end you'll find:

enter image description here

which leads to a trick:

ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 25}]] /. 
 HoldPattern[AppearanceElements -> _] -> (AppearanceElements -> None)

enter image description here

In the spirit of @Mr.Wizard comment you can also do something like:

ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 25}], 
  Paneled -> False] /. (AppearanceElements -> _) -> (AppearanceElements -> {})

which a bit changes things.

edited Oct 14 '12 at 09:42

answered Oct 14 '12 at 09:22

Vitaliy Kaurov

73,078
9
204
355

2

Nice trick. You don't need HoldPattern by the way. This still leaves the space for the controls; can you remove that too? – Mr.Wizard Oct 14 '12 at 09:25
1

@Mr.Wizard thanks :) hmmm... not sure about space. I added something at the end of the answer. – Vitaliy Kaurov Oct 14 '12 at 09:43
3

If you cannot apply AppearanceElements->None directly as an option, surely that must be a bug? – Mike Honeychurch Oct 14 '12 at 23:59
@MikeHoneychurch I'll see what I can find out. – Vitaliy Kaurov Oct 15 '12 at 00:07

kglr · Answer 2 · 2014-11-13T14:45:15.457

Update: go through the list every 2 seconds and stop after 5 repetitions:

list = Table[Plot[Sin[x + n], {x, 0, 3 Pi}, PlotRange -> {-1, 1}], {n, -2 Pi, 2 Pi, Pi/40}];

Dynamic[list[[Clock[{1, Length@list, 1}, 2, 5]]]]

enter image description here

Original post:

Since

ListAnimate generates a Manipulate object containing an Animator (docs)

With explicit lists as input, say,

 list = Table[Plot[Sin[x + n], {x, 0, 3 Pi}], {n, 0, 2 Pi, Pi/20}];

the animation produced by ListAnimate[list...] can also be produced using Manipulate or Animator specifying the Animator option settings directly (instead of post-processing the Manipulate object generated by ListAnimate).

Manipulate[list[[k]], {{k, 1, ""}, 1, Length[list], 1,
      ControlType -> Animator, AnimationRate -> 15, 
      AnimationRunning -> True, AppearanceElements -> {}},
  AppearanceElements -> None, Paneled -> False]

or

DynamicModule[{j},
  Column[{Animator[Dynamic[j], {1, Length@list, 1}, 15, 
       AnimationRunning -> True, AppearanceElements -> None], 
  Dynamic[list[[j]]]}]]

enter image description here

This is impressive as the file size is dramatically reduced, at least in my case working with DensityPlot +1. — José Antonio Díaz Navas, Oct 29 '22 at 11:41

score 3 · Answer 3 · answered Oct 14 '12 at 08:57

3

I don't know how to do that. Perhaps you are open to an alternative?

animate[list_List, rate_?Positive] := DynamicModule[{x = list},
  Dynamic[First[x = RotateLeft@x], UpdateInterval -> 1/rate, TrackedSymbols -> {}]]

list = Table[Plot[Sin[x + n], {x, 0, 3 Pi}], {n, 0, 2 Pi, Pi/20}];

animate[list, 15]

enter image description here

answered Oct 14 '12 at 08:57

Mr.Wizard

271,378
34
587
1,371

It's too slow on my machine but it's what I am looking for. ListAnimate looks 10x faster to me. I want to make an interactive user interface, so being fast is a must. – Helium Oct 14 '12 at 09:07
@Mohsen Yes, I see now that it's not very smooth. – Mr.Wizard Oct 14 '12 at 09:29

How can I completely remove the ListAnimate controls?

3 Answers3

Linked

Related