How can I make hatching filling of plot?

Question

How can I make a hatching filling of the plot?

Like this:

hatching filling plot

I used another plot with shifting to make the filled area above:

plot := ListLinePlot[
  Table[{x1[w], x2[w]}, {w, 1.5, 5, .005}],     
  Filling -> Top,
  FillingStyle -> White
  ]
fill := ListLinePlot[
  Table[{x1[w] - 0.01, x2[w] - 0.02}, {w, 1.5, 5, .005}],
  Filling -> Top,
  FillingStyle -> LightGray,
  PlotStyle -> LightGray
  ]
Show[fill, plot]

plot

How can I make hatching filling of the filled-plot?

Rojo · Accepted Answer · 2012-10-24T19:33:58.990

19

Something like this?

    RegionPlot[y < 1/x && y + 0.3 > 1/(x + 0.3) , {x, 0, 3}, {y, 0, 4}, 
  AxesOrigin -> {0, 0}, Frame -> False, Axes -> Automatic, Mesh -> 20,
   MeshFunctions -> {#1 - #2 &}, BoundaryStyle -> None]~Show~
 Plot[1/x, {x, 0, 3}]

Mathematica graphics

You can add PlotStyle -> Transparent to the RegionPlot if you don't want the blue filling, and xkcdify it

enter image description here

edited Oct 24 '12 at 19:33

answered Oct 24 '12 at 18:21

Rojo

42,601
7
96
188

Beware! The anti-xkcdification patrol is here! http://mathematica.stackexchange.com/a/13359/193 – Dr. belisarius Oct 24 '12 at 22:12
1

@belisarius, oh, but it very much fits the context. I'll defend it as if it was Howgartz against any evil wizard – Rojo Oct 25 '12 at 01:39
+1 for the "evil wizard" ... but your adjectives are too harsh! – Dr. belisarius Oct 25 '12 at 01:49
5

You may always sweeten the answer by throwing in some infix notation. – Yves Klett Oct 25 '12 at 12:33
One more question. I get hatches, but I can't combine it with main plot. I used: Show[ RegionPlot[x1[w] > x2[g] && (x1[w + 0.2]) < (x2[g + 0.2]), {w, 1.5, 5}, {g, 1.5, 5}, AxesOrigin -> {0, 0}, Axes -> Automatic, PlotStyle -> Transparent, Frame -> False, Mesh -> 20, BoundaryStyle -> None, MeshFunctions -> {#1 - #2 &} ], ParametricPlot[{x1[w], x2[w]}, {w, 1.5, 5}] ] I'd tried ListLinePlot, ParametricPlot and both orders. But it's show only the first plot. Also, I tried another RegionPlot, but I don't think that is good way. Which way is better? – shed Oct 26 '12 at 11:43
@shed, it should show both, but that ParametricPlot isn't describing the borders of your region. Are you sure that's what you want to plot? Probably there's a scaling issue – Rojo Oct 26 '12 at 13:42
1

@shed, if you want to plot the borders of that region, I'd go with ContourPlot[x1[w] == x2[g], {w, 1.5, 5}, {g, 1.5, 5}] – Rojo Oct 26 '12 at 13:55
1

@shed you probably should accept this one, or you are still hoping for something different? – Rojo Dec 09 '13 at 22:13

Syed · Answer 2 · 2024-02-18T11:23:07.527

Using Region functionality:

Clear["Global`*"];
Show[Plot[1/x
  , {x, 0, 1}
  , PlotStyle -> Black
  , PlotRange -> {0, 7}
  , RegionFunction -> Function[{x, y}, x > 0]
  , AxesLabel -> TraditionalForm /@ {x[t], y[t]}
  , LabelStyle -> Directive[Black, Medium]
  ]
 , RegionPlot[y < 1/x && y > 0.8/x - 0.2
  , {x, 0, 1}, {y, 0, 7}
  , BoundaryStyle -> None
  , PlotStyle -> {Black, HatchFilling[1, 0.1, 12]}
  ]
 ]

How can I make hatching filling of plot?

2 Answers2

Linked

Related