63

There are commands like NonlinearModelFit[] or NDSolve[] that have the option Method it typically defaults to Automatic. How can you check after the evaluation of the command which method Mathematica picked?

J. M.'s missing motivation
  • 124,525
  • 11
  • 401
  • 574
uli
  • 1,365
  • 13
  • 13
  • Some functions have their defaults indicated in the manual. As an example, for solving (systems of) ODEs with NDSolve[], by default it switches between "BDF" and "Adams", depending on whether the system being solved is stiff or not. If you're performing nonlinear least squares with FindFit[], Mathematica is smart enough to automatically use "LevenbergMarquardt". – J. M.'s missing motivation Jan 18 '12 at 11:30
  • 2
    Of course, that is what Mathematics does. But how do I check? I can use Options to check which ones were given. But there is no such thing like Method[%] that informs me what Mathematics did. If I publish results I cannot write "The fitting was probably done with LevenbergMarquardt, but I can’t tell for sure, because there is no command to check." – uli Jan 18 '12 at 11:34
  • 1
    This mentions some of the defaults taken. – J. M.'s missing motivation Jan 18 '12 at 11:34
  • 1
    "If I publish results I cannot write..." - ergo, you should try to specify options explicitly if you want everything to be transparent. – J. M.'s missing motivation Jan 18 '12 at 11:36
  • 1
    @uli: +1 It's an interesting question and I'm not sure that you'll find a satisfactory answer. I guess if you want to publish the results you can either specify the Mma version number you used, or manually choose the method that you use. – Simon Jan 18 '12 at 11:43
  • Still I’d would like to know Mathematica’s choice. Especially if it deviates from the default. ODEs are not my field of expertise, but is it decidable whether a system is stiff or not? Perhaps behind the various Automatic-options there are only heuristics, that may give a wrong classification? – uli Jan 18 '12 at 11:54
  • 1
    "...is it decidable whether a system is stiff or not?" - it's not entirely foolproof, but Mathematica does have stiffness detection methods. See this and this for instance. – J. M.'s missing motivation Jan 18 '12 at 12:00

3 Answers3

53

I think you can actually see (most of) what Mathematica is doing by using Trace[..., TraceInternal -> True].

For example, 

Select[Flatten[
  Trace[NDSolve[y'[x] == x && y[0] == 0, y, {x, 0, 6}], 
   TraceInternal -> True]], ! FreeQ[#, Method | NDSolve`MethodData] &]

shows the DE was evaluated using NDSolve`LSODA and Newton's method. (I think)

And

Select[Flatten[
  Trace[NDSolve[{Derivative[1][x][t]^2 + x[t]^2 == 1, x[0] == 1/2}, 
    x, {t, 0, 10 Pi}, SolveDelayed -> True], 
   TraceInternal -> True]], ! FreeQ[#, Method | NDSolve`MethodData] &]

used NDSolve`IDA.

As an aside, here's something I just learnt from Trott's Mathematica guidebook for numerics, to see all of the methods and suboptions for NDSolve 

{#, First /@ #2} & @@@ 
 Select[{#, Options[#]} & /@ (ToExpression /@ 
   DeleteCases[Names["NDSolve`*"],(* PDE method only *) "NDSolve`MethodOfLines"]), 
   (Last[#] =!= {}) &]
Simon
  • 10,167
  • 5
  • 57
  • 72
  • I just saw ruebenko's answer. Using TraceInternal as above seems to give the same list of methods as his data, but it requires a lot of digging... – Simon Jan 18 '12 at 12:04
  • 1
    You can also use the second argument of Trace; for example, Trace[NDSolve[..], _NDSolve`InitializeMethod | _[NDSolve`MethodData[___]], TraceInternal -> True] – Michael E2 Jan 24 '17 at 00:04
  • @Simon, to check which method was chosen by NSolve instead of NDSolve, I changed ! FreeQ[#, Method | NDSolveMethodData] &to! FreeQ[#, Method | NSolve`MethodData] &`, but it seems not to work, could you give some suggestions? Thank you! – Nobody Nov 30 '23 at 10:07
19

For NDSolve with one step methods you can use the MethodMonitor.

data = Last[
   Reap[sol = 
      NDSolve[{y'[x] == y[x] Cos[x + y[x]], y[0] == 1}, y, {x, 0, 30},
        Method -> "StiffnessSwitching", 
       "MethodMonitor" :> (Sow[NDSolve`Self[[0]]];)];]];

See:

tutorial/NDSolveStiffnessTest
tutorial/NDSolveExtrapolation

Adams, BDF, IDA are multi-step methods and do not work with this approach.

Simon
  • 10,167
  • 5
  • 57
  • 72
12

I asked this question once after a presentation by Jon McLoone. His answer was that that was not possible and that Mathematica can switch methods many times if the situation asks for it. So it wouldn't be useful either. I agree that this is not completely satisfactory.

Sjoerd C. de Vries
  • 65,815
  • 14
  • 188
  • 323