Find prefix of list in Association

Question

I am trying to write some kind of demonstration for coding algorithm (for prefix codes).
I have an Association that contains lists of bits (0s and 1s):

<|{"1"} -> "a", {"0", "1"} -> "b", {"0", "0"} -> "c"|>

And a list that represents a coded string (which in our example aabc):

{1,1,0,1,0,0}

And Im trying to write a code that searches for a match between a prefix (of any length) from my coded string with a key in the association (without loops). If I would use a loop I would try to find a prefix in the coded string in increasing length (first look for a match in length 1, then in 2 and so on..).
For now, my goal is to find a match, remove it from the list, and find the next matching. In case I am going wrong with this idea (in the matter of efficiency), I would thank you if you suggest me better ideas.
I have tried to search online and in the forum but without any success.
Any tip will be appreciated !
Thank you

I am not sure I understand the question, but I think you are looking for some sort of prefix tree (trie) search and retrieval and that is discussed in MSE here: "Can a Trie be implemented efficiently?". Specifically this answer should be a good start to do what you want. — Anton Antonov, May 20 '17 at 15:54
Thank you for your reply, I am trying to find a more simple solution for this problem. For now, I'm just trying to find a prefix that exists in the Association. Maybe a similar parallel problem will be to find the first sub-sequence that is an element in an other list. — kobibo, May 20 '17 at 16:16
What output do you expect for the example input given? Do you want to get back "aabc"? — Mr.Wizard, May 20 '17 at 16:45
@Kobo01 This may work for small code but will not be efficient for large code especially 30 k. I think @WReach's approach is the best one — Ali Hashmi, May 20 '17 at 19:22

score 8 · Accepted Answer · answered May 20 '17 at 17:31

8

If you are willing to use a simple string representation, then StringReplace might be adequate for your purpose:

decode[s_] := StringReplace[s, {"1" -> "a", "01" -> "b", "00" -> "c"}]

decode["110100"]
(* "aabc" *)

decode["101100101"]
(* "abacab" *)

answered May 20 '17 at 17:31

WReach

68,832
4
164
269

Works Amazing ! Thank you ! – kobibo May 20 '17 at 18:35

score 5 · Answer 2 · answered May 20 '17 at 16:57

5

This is probably not highly efficient but I think it does what you describe.

asc = <|{1} -> "a", {0, 1} -> "b", {0, 0} -> "c"|>;
code = {1, 1, 0, 1, 0, 0};

rls = KeyValueMap[Append[#, x___] :> (Sow[#2]; {x}) &, asc] // Dispatch;

Reap[code //. rls;][[2, 1]]

{"a", "a", "b", "c"}

Note that I replaced string "0" and "1" in the Association with integer 0 and 1 for consistency with the coded string (code).

answered May 20 '17 at 16:57

Mr.Wizard

271,378
34
587
1,371

Thank you very much, It worked fine, but took 2 minutes to evalute for a 30kB string... – kobibo May 20 '17 at 18:36

Ali Hashmi · Answer 3 · 2017-05-20T19:16:27.990

2

asc = <|{1} -> "a", {0, 1} -> "b", {0, 0} -> "c"|>;

func[assoc_Association, code : {(1 | 0) ..}] := 
Map[assoc[#] &][SequenceCases[code, Alternatives @@ Keys@assoc]];

func[asc,{1, 1, 0, 1, 0, 0}]
(* {"a", "a", "b", "c"} *)

code = {1, 0, 1, 1, 0, 0, 1, 0, 1};
func[asc,code]
(* {"a", "b", "a", "c", "a", "b"} *)

edited May 20 '17 at 19:16

answered May 20 '17 at 19:04

Ali Hashmi

8,950
4
22
42

Find prefix of list in Association

3 Answers3