Reverse colors in color scheme

Question

I have a SwatchLegend with a color scheme:

SwatchLegend[10, {"a", "b", "c", "d", "e", "f", "g"}, 
 LegendLayout -> {"Row", 1}, 
 LabelStyle -> {FontSize -> 16, Bold, Black, FontFamily -> "Arial"}, 
 LegendMarkerSize -> 16]

How can I reverse the colors in the color scheme?

Answer 1

The trick is to go to ColorData. That 10 means ColorData[10], so you can do this:

With[{divs = {"a", "b", "c", "d", "e", "f", "g"}}, 
 SwatchLegend[
  ColorData[10][Length[divs] - # + 1] & /@ Range@Length[divs],
  divs, 
  LegendLayout -> {"Row", 1}, 
  LabelStyle -> {FontSize -> 16, Bold, Black, FontFamily -> "Arial"}, 
  LegendMarkerSize -> 16]
 ]

Answer 2

You don't have to reverse colors in color scheme.

Instead, you can simply Reverse your label list and use "ReversedRow" layout:

SwatchLegend[10, Reverse@{"a", "b", "c", "d", "e", "f", "g"}, 
 LegendLayout -> {"ReversedRow", 1}, 
 LabelStyle -> {FontSize -> 20, Bold, Black, FontFamily -> "Arial"}, 
 LegendMarkerSize -> 30]

Similarly, for PointLegend and LineLegend:

PointLegend[10, Reverse@{"a", "b", "c", "d", "e", "f", "g"}, 
 LegendLayout -> {"ReversedRow", 1}, 
 LabelStyle -> {FontSize -> 20, Bold, Black, FontFamily -> "Arial"}, 
 LegendMarkers -> {"\[FilledCircle]", 30}]

LineLegend[10, Reverse@{"a", "b", "c", "d", "e", "f", "g"}, 
 LegendLayout -> {"ReversedRow", 1}, 
 LabelStyle -> {FontSize -> 20, Bold, Black, FontFamily -> "Arial"}, 
 LegendMarkerSize -> 50]

Answer 3

data = {"a", "b", "c", "d", "e", "f", "g"};

SwatchLegend[
 ColorData[10, "ColorList"][[Length@data ;; 1 ;; -1]], data,
 LegendLayout -> {"Row", 1},
 LabelStyle -> {FontSize -> 16, Bold, Black, FontFamily -> "Arial"},
 LegendMarkerSize -> 16]