Flipping y-axis and keeping x-axis ticks and label on top

Question

Consider the following plot:

Plot[x, {x, 1, 10}, Frame -> True]

How can the plot be inverted in the y axis such that the x axis ticks and label will remain on top, for example

There are two posts with similar questions, but they do not keep the x axis on top and seem to not use Mathematica's abilities to their full extent so I did not find them useful:

How to reverse the direction of the y axes. – AccidentalFourierTransform May 05 '18 at 15:50 — AccidentalFourierTransform, May 05 '18 at 15:50

corey979 · Accepted Answer · 2018-05-05T17:46:23.920

3

Plot[x, {x, 1, 10}, Frame -> True, Axes -> False, 
 ScalingFunctions -> "Reverse", 
 FrameTicks -> {{Automatic, Automatic}, {Automatic, All}}, 
 FrameTicksStyle -> {{Automatic, Automatic},
                     {Directive[FontOpacity -> 0, FontSize -> 0], Automatic}},
 FrameLabel -> {{"y", None}, {None, "x"}}]

or

Plot[x, {x, 1, 10}, Frame -> True, Axes -> False, 
 ScalingFunctions -> "Reverse", 
 FrameTicks -> {{Automatic, Automatic}, {Automatic, All}}, 
 ImagePadding -> {{Automatic, Automatic}, {1, Automatic}},
 FrameLabel -> {{"y", None}, {None, "x"}}]

edited May 05 '18 at 17:46

answered May 05 '18 at 15:49

corey979

23,947
7
58
101

The frame label of the x axis appears below in the first suggestion, and don't appear at all in the second when adding FrameLabel->{"x","y"}. Can you address that in your answer? – jarhead May 05 '18 at 16:04
See the edited answer. – corey979 May 05 '18 at 17:46

score 1 · Answer 2 · answered May 05 '18 at 16:35

You can use the internal functions Charting`ScaledTicks and Charting`ScaledFrameTicks to draw ticks with or without labels:

Plot[
    x,
    {x, 1, 10},
    Frame -> True, 
    ScalingFunctions->"Reverse",
    FrameTicks -> {
        {Automatic, Automatic},
        {
            Charting`ScaledFrameTicks[{Identity,Identity}], 
            Charting`ScaledTicks[{Identity,Identity}]
        }
    }
]

Flipping y-axis and keeping x-axis ticks and label on top

2 Answers2