Angle increment spiral in Mathematica

Question

What method cold I use to obtain a Plot similar to the one in the picture?

Have you already tried to plot something yourself? Generally you’ll get more bites if you actually tried something...posting the code you used aswell is helpful. — DrMrstheMonarch, May 15 '19 at 17:41
Related: Pentagonal spiral in Mathematica. The figure you are asking for is actually produced in the question text of Filling Space with Pursuit Polygons, although the question is not really about this figure. — C. E., May 15 '19 at 17:45

score 20 · Answer 1 · answered May 15 '19 at 17:47

Here is an adaptation of my answer here:

steps = Table[{r, 1.005 (2 Pi/4)}, {r, 1, 25, 0.2}];
Graphics[{Black, Line@AnglePath[steps]}, Background -> White]

Mathematica graphics

The spiral tendency is controlled by the value 1.005 in the code, and the spacing between the lines is controlled by the value 0.2.

score 11 · Answer 2 · answered May 15 '19 at 18:09

Not really an answer, since this isn't a single line but I thought it was interesting so I'll post it.

rc = Rectangle[];
center = {0.5, 0.5};
transforms = Table[
    ScalingTransform[{x, x}, center] @* RotationTransform[(1 + -x) * Pi / 4, center],
    {x, 1, 0.025, -0.025}
];
Graphics @ {EdgeForm @ Black, FaceForm @ None, GeometricTransformation[rc, transforms]}

score 10 · Answer 3 · answered May 16 '19 at 21:00

Um, I like spirals. So as @C.E. points out, AnglePath is a useful function.

 Manipulate[
    Graphics[{Thick,
       MapIndexed[{ColorData[cs, (#2[[1]]*d)^e], Line[#]} &,
          Partition[AnglePath[Table[{r, a*Degree}, {r, 0, 1., d}]], 2, 1]]
    }, Background -> Black, ImageSize -> 500],
    {{d, 0.01, "Step Increment"}, 0.002, 0.02, Appearance -> "Labeled"},
    {{a, 119., "Angle Increment (Degree)"}, 1., 180., Appearance -> "Labeled"},
    {{e, 1.5, "Colour Exponent"}, 0.1, 3.0, Appearance -> "Labeled"},
    {{cs, "SandyTerrain", "Colour Scheme"}, ColorData["Gradients"]}
 ]

There is an interesting optical illusion when scrolling this figure up and down quickly! — Gustavo Delfino, May 17 '19 at 02:34

Angle increment spiral in Mathematica

3 Answers3