How to remove the extra space on the left and the right of the default BarChart?

Question

pbdomains = <|
       "Overall " -> Around[2.6, 0.04], 
       "PB" -> Around[4.25, 0.06]
|>;

BarChart[pbdomains, ChartStyle -> "BrightBands", 
 LabelStyle -> {FontFamily -> "Times New Roman", 28, Bold, 
   GrayLevel[0]}, Frame -> True, FrameLabel -> {"", " Count"}, 
 BarSpacing -> Tiny, 
 ChartLabels -> Callout[Automatic, Above, Appearance -> "Balloon"]]

@Carl Lange . Many thanks! – SelfHorizons Work May 26 '19 at 22:08 — SelfHorizons Work, May 26 '19 at 22:08
Add PlotRange -> {{0.5, 2.5}, All}. – Rohit Namjoshi May 26 '19 at 23:31 — Rohit Namjoshi, May 26 '19 at 23:31
@Rohit Namjoshi. Thanks so much! – SelfHorizons Work May 27 '19 at 03:51 — SelfHorizons Work, May 27 '19 at 03:51

score 2 · Answer 1 · answered May 27 '19 at 03:53

Based on Rohit Namjoshi solution:

pbdomains = <|"Overall " -> Around[2.6, 0.04], 
   "PB" -> Around[4.25, 0.06]|>;

BarChart[pbdomains, ChartStyle -> "BrightBands", 
 LabelStyle -> {FontFamily -> "Times New Roman", 28, Bold, 
   GrayLevel[0]}, Frame -> True, FrameLabel -> {"", " Count"}, 
 BarSpacing -> Tiny, 
 ChartLabels -> Callout[Automatic, Above, Appearance -> "Balloon"], 
 PlotRange -> {{0.5, 2.5}, All}]

score 2 · Accepted Answer · answered May 27 '19 at 11:24

You can use PlotRangePadding.

pbdomains = <|
       "Overall " -> Around[2.6, 0.04], 
       "PB" -> Around[4.25, 0.06]
|>;

BarChart[pbdomains, ChartStyle -> "BrightBands", 
 LabelStyle -> {FontFamily -> "Times New Roman", 28, Bold, 
   GrayLevel[0]}, Frame -> True, FrameLabel -> {"", " Count"}, 
 BarSpacing -> Tiny, 
 ChartLabels -> Callout[Automatic, Above, Appearance -> "Balloon"],
 PlotRangePadding -> {{-1.4, -1.37}, {None, Scaled[0.2]}}]

kglr · Answer 3 · 2020-08-15T07:38:03.810

1. Use the (undocumented) option "FixedBarSpacing" as "FixedBarSpacing" -> True or as Method -> {"FixedBarSpacing" -> True}

BarChart[pbdomains, ChartStyle -> "BrightBands", 
  LabelStyle -> {FontFamily -> "Times New Roman", 28, Bold, 
      GrayLevel[0]}, Frame -> True, FrameLabel -> {"", " Count"}, 
  ChartLabels -> Callout[Automatic, Above, Appearance -> "Balloon"],
  "FixedBarSpacing" -> True]

2. Use {pbdomains} as the first argument and use the option BarSpacing -> {Tiny, 1}:

BarChart[{pbdomains},
  BarSpacing -> { Tiny, 1},
  ChartStyle -> "BrightBands", 
  LabelStyle -> {FontFamily -> "Times New Roman", 28, Bold, GrayLevel[0]}, 
  ImageSize -> Large, Frame -> True, FrameLabel -> {"", " Count"}, 
  ChartLabels -> Callout[Automatic, Above, Appearance -> "Balloon"]]

How to remove the extra space on the left and the right of the default BarChart?

3 Answers3

Linked