Find all permutations with a condition

Question

How can I find all the permutations of {a, b, c} where a + b + c = n?

For instance: if n = 3 the permutations I seel are:

Permutations[{3, 0, 0}]
Permutations[{2, 1, 0}]
{1, 1, 1}

good find @Mr.Wizard ! I searched for ages permutations-related questions but not IntegerPartitions... — Filippo Vitale, Mar 11 '13 at 06:49

score 19 · Accepted Answer · edited Mar 11 '13 at 05:08

19

f[sum_, quant_] :=
  Flatten[Permutations /@ IntegerPartitions[sum, {quant}, Range[0, sum]], 1]

f[3, 3] // Column
(*
{3,0,0}
{0,3,0}
{0,0,3}
{2,1,0}
{2,0,1}
{1,2,0}
{1,0,2}
{0,2,1}
{0,1,2}
{1,1,1}
*)

f[4, 2] // Column
(*
{4,0}
{0,4}
{3,1}
{1,3}
{2,2}
*)

edited Mar 11 '13 at 05:08

m_goldberg

107,779
16
103
257

answered Mar 10 '13 at 23:32

Dr. belisarius

115,881
13
203
453

score 8 · Answer 2 · edited Mar 11 '13 at 07:07

8

f[sum_, quant_] := FrobeniusSolve[Array[1 &, quant], sum]

f[3, 3]

(*
    {{0, 0, 3}, {0, 1, 2}, {0, 2, 1}, {0, 3, 0}, {1, 0, 2}, {1, 1, 1},
    {1, 2, 0}, {2, 0, 1}, {2, 1, 0}, {3, 0, 0}}
*)

f[4, 2]

(* {{0, 4}, {1, 3}, {2, 2}, {3, 1}, {4, 0}} *)

edited Mar 11 '13 at 07:07

m_goldberg

107,779
16
103
257

answered Mar 11 '13 at 05:52

chyanog

15,542
3
40
78

1

For readibility purpose, may I suggest: ConstantArray[1, quant] instead of Array[1 &, quant] ? – Filippo Vitale Mar 11 '13 at 08:49

score 1 · Answer 3 · answered Jan 05 '17 at 11:10

1

(* a crude way: lets assume we wish to find all the permutations of a list of three integers that add up to 4 *)

Select[Permutations[Flatten@ConstantArray[Range[0, 4], 3], {3}], 
Plus @@ # == 4 &]

answered Jan 05 '17 at 11:10

Ali Hashmi

8,950
4
22
42

Find all permutations with a condition

3 Answers3

Linked

Related