Why is EigenValues returning Root expressions?

Question

This is the code I have:

ϵs = -13.6;
ϵso = -29.1;
ϵp = -14.1;
ssσ = -7.20;
spσ = 9.46;

θ = ((π - β)/2);

Hmatrix0[θ_] = 
{
  {ϵs, 0, ssσ, Cos[θ]*spσ, -Sin[θ]*spσ, 0}, 
  {0, ϵs, ssσ, -Cos[θ]*spσ, -Sin[θ]*spσ, 0}, 
  {ssσ, ssσ, ϵso, 0, 0, 0}, 
  {Cos[θ]*spσ, -Cos[θ]*spσ, 0, ϵp, 0, 0}, 
  {-Sin[θ]*spσ, -Sin[θ]*spσ, 0, 0, ϵp, 0}, 
  {0, 0, 0, 0, 0, ϵp}
}

Eigenvalues[Hmatrix0[θ]]

This is a sample of one of the eigenvalues:

Root[(38319.6 + 0. I) - 130827. Cos[β] - 116527. Cos[2 β] + (120228. - 9278.49 Cos[β] - 4004.37 Cos[2 β]) #1 + (29612. + 9.09495*10^-13 Cos[β]) #1^2 + 2480.29 #1^3 + 84.5 #1^4 + 1. #1^5 &, 1]

I wish to plot the eigenvalues as a function of beta as it ranges from $\frac{\pi}{2}$ to $\pi$ but I don't know what those hashes are and putting N[hmatrix0[$\beta$]] doesn't work.

You forgot to define \[Beta]; N will work if it is numerically defined. — Mr.Wizard, Mar 14 '13 at 05:36
@Mr.Wizard, how do I make beta a variable that ranges from pi/2 to pi? — user17338, Mar 14 '13 at 05:44
@Mark please make that an answer; there's no point sticking it in the question like that. :-) — Mr.Wizard, Mar 14 '13 at 05:57
Those aren't "hashtags" - look up Slot in the documentation. — Verbeia, Mar 14 '13 at 05:57
@Mr.Wizard Will do. Generally, though, if you want to close something as too localized, it really doesn't matter to me. I just had something typed up and figured I'd put it in there for the OP's sake. — Mark McClure, Mar 14 '13 at 06:04
Closely related: Mathematica won't give eigenvectors but Wolfram Alpha will? What am I doing wrong? if not a duplicate. — Artes, Aug 13 '13 at 12:50

score 10 · Accepted Answer · answered Mar 14 '13 at 06:08

First, you need to keep your $\theta$s and $\beta$s straight. Let's define the matrix in terms of $\theta$ and worry about the relationship with $\beta$ in a bit.

epss = -13.6;
epsso = -29.1;
epsp = -14.1;
sssigma = -7.20;
spsigma = 9.46;
Hmatrix0[theta_] = {
  {epss, 0, sssigma, Cos[theta]*spsigma, -Sin[theta]*spsigma, 0}, 
  {0, epss, sssigma, -Cos[theta]*spsigma, -Sin[theta]*spsigma, 0}, 
  {sssigma, sssigma, epsso, 0, 0, 0}, 
  {Cos[theta]*spsigma, -Cos[theta]*spsigma, 0, epsp, 0, 0}, 
  {-Sin[theta]*spsigma, -Sin[theta]*spsigma, 0, 0, epsp, 0}, 
  {0, 0, 0, 0, 0, epsp}
};

Now, we can make your plot as follows.

Plot[Evaluate[Eigenvalues[Hmatrix0[(Pi - theta)/2]]],
  {theta, Pi/2, Pi}, PlotStyle -> Thick]

enter image description here

Why is EigenValues returning Root expressions?

1 Answers1

Linked