How to remove duplicate elements

Question

How to remove duplicate elements? I want to delete all the same elements in a list. For example, list {1,2,1,2,3,4,5,1}, I want to get {3,4,5}.

And using DeleteDuplicates function can not achieve the desired purpose: DeleteDuplicates[{1, 2, 1, 2, 3, 4, 5, 1}]

I know this method at present: {1, 2, 1, 2, 3, 4, 5, 1} // Tally // Cases [{x_, 1}:> x], but I also want to know more ingenious methods.

for fun: {1, 2, 1, 2, 3, 4, 5, 1} //. {a___, b_, c___, b_, d___} :> DeleteCases[{a, c, d}, b]. — AccidentalFourierTransform, Mar 01 '20 at 21:05
@user1066 Thanks for linking that. This appears to be a duplicate and I am marking it as such. If I have missed an important distinction please let me know and I shall reopen. — Mr.Wizard, Mar 02 '20 at 09:19
Also for fun (revised): Reap[Sow[1,list], _, Pick[#1,#2, {1}]&][[2]] — user1066, Mar 02 '20 at 18:50
How ironic is it that a question about removing duplicates is a duplicate? — bluestool, Mar 22 '20 at 14:17

score 17 · Accepted Answer · answered Mar 01 '20 at 09:10

17

list = {1, 2, 1, 2, 3, 4, 5, 1};

Keys@Select[Counts[list], # == 1 &]
(* {3, 4, 5} *)

answered Mar 01 '20 at 09:10

Szabolcs

234,956
30
623
1,263

1

Or more functional perhaps: Keys@Select[Counts[list], EqualTo[1]] – SHuisman Mar 01 '20 at 10:20
4

@SHuisman If you want to go operator, go all the way :-) Keys@Select[EqualTo[1]]@Counts[list] – Szabolcs Mar 01 '20 at 10:52
4

Keys@*Select[EqualTo[1]]@*Counts is even more operator. – Roman Mar 01 '20 at 13:15
1

I like that this will preserve order. Several of the methods shown below do not. For example, switch the position of 3 and 4 and re-run the methods below. Instead of {4,3,5}, they return {3,4,5}. The method from OP also preserves the order. – Mark R Mar 01 '20 at 19:06

score 8 · Answer 2 · answered Mar 01 '20 at 09:31

8

With[{t = Tally[#]}, Pick[t[[All, 1]], t[[All, 2]], 1]] &

Should outperform, hardly "ingenious "...

answered Mar 01 '20 at 09:31

ciao

25,774
2
58
139

score 7 · Answer 3 · answered Mar 01 '20 at 09:09

7

Without pattern matching:

Sort[{1, 2, 1, 2, 3, 4, 5, 1}] // 
  Split // 
  Select[Length[#] == 1 &] //
  Flatten[#, 1] &

answered Mar 01 '20 at 09:09

sakra

5,120
21
33

score 7 · Answer 4 · answered Mar 01 '20 at 18:54

7

For variety:

lst = {1, 2, 1, 2, 3, 4, 5, 1};

lst //. {OrderlessPatternSequence[Repeated[x_, {2, ∞}], a___]} :> {a}

{3, 4, 5}

answered Mar 01 '20 at 18:54

kglr

394,356
18
477
896

score 5 · Answer 5 · answered Mar 02 '20 at 07:49

5

A Rube Goldberg solution:

☺1 /: {♯♯___, ☺1 @ ♯_, ♯♯♯___} := {♯♯, ♯♯♯} /. ♯ | ☺1 @ ♯ -> (## &[])
☺2 = (☺3 @ ♯_ := (☺3 @ ♯ = ☺1 @ ♯; ♯); ☺3 /@ #) &;

☺2 @ {1, 2, 1, 2, 3, 4, 5, 1}

{3, 4, 5}

answered Mar 02 '20 at 07:49

kglr

394,356
18
477
896

1

I LOL'd. +1 internet cookie for you. – ciao Mar 02 '20 at 07:56
I LOL'd. +1 internet cookie for you. – A little mouse on the pampas Feb 26 '21 at 02:40

How to remove duplicate elements

5 Answers5

Linked