Pattern matching for repeated elements

Question

Is there a pattern that can match repeated elements that appear more than twice in a row?

For the sake of example let's say I want to use pattern matching to delete subsequent duplicate:

l = {1,2,2,3,4};
l/.{b___,x_,x_,r___}->{b,r}
({1,3,4})

But

l = {1,2,2,2,3,4};
l/.{b___,x_,x_,r___}->{b,r}
({1,2,3,4})

I can try to use Repeated, but it doesn't seem to work:

l = {1, 2, 2, 2, 3, 4};
l /. {b___, x_, (x_) .., r___} -> {b, r}
({1,2,3,4})

Am I using it wrong?

Answer 1

Use the Longest pattern command to find the longest repeated sequence that matches the pattern.

l = {1, 2, 2, 2, 3, 4};
l /. {b___, x_, Longest[(x_) ..], r___} :> {b, r}
({1, 3, 4})

Answer 2

Another possibility is to use SequenceReplace:

SequenceReplace[{1, 2, 2, 2, 3, 4}, {x_, x_ ..} -> Sequence[]]

{1, 3, 4}

Answer 3

Try the following:

l = {1, 2, 2, 2, 3, 4};
l /. {b___, x_, (x_) .., r___} -> {{b}, {r}}
(* {{1}, {2, 3, 4}} *)

and you see that that r is ill-defined. Therefore we must restrict r:

l //. {b___, Repeated[x_, {2, 10}], Shortest@r___} :> {b, r}
(*{1, 3, 4}*)

Answer 4

You might also consider using the two-argument form of Repeated for finer control:

{1, 2, 2, 3, 4}  /. {a___, Repeated[x_, {2, ∞}], b___} :> {a, b}

{1, 3, 4}

SequenceReplace[{1, 2, 2, 2, 3, 4}, {Repeated[x_, {2, ∞}]} -> Sequence[]]

{1, 3, 4}

Answer 5

Not pattern matching, but one other way:

Cases[Split@l2, {x_}:>x]

{1, 3, 4}

Answer 6

Cases[{a_, 1} :> a] @ Tally @ list

{1, 3, 4}

Or:

Keys @ Select[SameAs @ 1] @ Counts @ list

{1, 3, 8}

Answer 7

Using Select and Count:

l = {1, 2, 2, 2, 3, 4};
Select[l, Count[l, #] == 1 &]
({1, 3, 4})

Also, using ReplaceAll:

f = # /. x_Integer :> If[Count[#, x] == 1, x, Nothing] &;
f@l
({1, 3, 4})

Also, using the third argument of GroupBy and Lookup:

Lookup[GroupBy[Normal@Counts[l], #[[2]] == 1 &, #[[All, 1]] &], True]
({1, 3, 4})