What is the inverse of CoefficientList?

Question

I have numbers in vector notation. I need to get polynomial notation from them.

My numbers are {0, 1, 23, 5, 15, 0, 0, 0}. I want to get $x + 23x^2 + 5x^3 + 15x^4$ from this list.

How can I get that polynomial?

Related question: http://mathematica.stackexchange.com/questions/21340/dynamic-application-of-several-polynomials — Michael E2, Mar 31 '13 at 18:37

m_goldberg · Answer 1 · 2013-03-31T02:56:17.190

16

The following (taken from the Mathematica documentation) will do what you ask.

Expand[FromDigits[Reverse[{0, 1, 23, 5, 15, 0, 0, 0}], x]]

x + 23 x^2 + 5 x^3 + 15 x^4

I found the needed code in Properties & Relations section of the documentation page on CoefficientList. In general, it is a good idea to look for information on inverses in the Properties & Relations section of any function of interest.

edited Mar 31 '13 at 02:56

answered Mar 31 '13 at 02:49

m_goldberg

107,779
16
103
257

score 15 · Answer 2 · edited Apr 13 '17 at 12:55

15

The undocumented function Internal`FromCoefficientList is as close as one would get to InverseCoefficientList.

Examples:

cl = {0, 1, 23, 5, 15, 0, 0, 0};
Internal`FromCoefficientList[cl, x]

x + 23 x^2 + 5 x^3 + 15 x^4

cl2 = CoefficientList[(1 + x + 2 y)^2, {x, y}]

{{1, 4, 4}, {2, 4, 0}, {1, 0, 0}}

FullSimplify[Internal`FromCoefficientList[cl2, {x, y}]]

(1 + x + 2 y)^2

See also: this answer by Adam Strzebonski (thanks: Mr. Wizard for the reference)

Timings using @Mr.Wizard's set-up and timeAvg:

n = 5000;
c = RandomInteger[30, n];

Expand[Fold[(#1 \[FormalX] + #2) &, 0, Reverse[c]]] // timeAvg  (* 3.250000 *)
Expand@FromDigits[Reverse@c,  x] // timeAvg                     (* 0.039375 *)
MapIndexed[#1*x^(#2 - 1) &, c] // Total // timeAvg              (* 0.019375 *)
Total[c*x^(Range@n - 1)] // timeAvg                             (* 0.005375 *)
c.(x^Range[0, n - 1]) // timeAvg                                (* 0.003875 *)
Internal`FromCoefficientList[c, x] // timeAvg                   (* 0.003500 *)

edited Apr 13 '17 at 12:55

Community

1

answered May 10 '15 at 01:36

kglr

394,356
18
477
896

First mentioned on Stack Exchange here as far as I can tell. +1 for posting it in a place people can find it. – Mr.Wizard May 10 '15 at 11:46
Thank you @Mr.W for the link and the vote. – kglr May 10 '15 at 12:00
@Mr.Wizard thanks for the link, I was able to update that original bug. – rcollyer Aug 14 '15 at 15:15
Just to add on how could this be done with documented functions: rules = (#2 - {1}) -> #1 & @@@ MapIndexed[Rule, cl]; FromCoefficientRules[rules, x]. – corey979 Jan 06 '17 at 23:46

score 9 · Answer 3 · answered Mar 31 '13 at 05:36

Dot can be very efficient here:

c.(x^Range[0, Length@c - 1])

x + 23 x^2 + 5 x^3 + 15 x^4

Comparative timings:

n = 5000;
c = RandomInteger[30, n];

SetAttributes[timeAvg, HoldFirst]
timeAvg[func_] := Do[If[# > 0.3, Return[#/5^i]] & @@ Timing@Do[func, {5^i}], {i, 0, 15}]

Expand @ FromDigits[Reverse@c, x] // timeAvg
Total[c * x^(Range@n - 1)] // timeAvg
MapIndexed[#1*x^(#2 - 1) &, c] // Total // timeAvg
c.(x^Range[0, n - 1]) // timeAvg

0.03616

0.004992

0.01744

0.003616

I also like this formulation though it is not quite as fast:

c.Array[x^# &, n, 0]

score 6 · Answer 4 · answered May 10 '15 at 04:01

6

I vastly prefer using Horner for reconstructing polynomials from their coefficients. To wit:

Fold[(#1 \[FormalX] + #2) &, 0, Reverse[{0, 1, 23, 5, 15, 0, 0, 0}]] // Expand

returns your polynomial. In fact, this is effectively what FromDigits[] does internally for integer digits. Removing the Expand[] yields what would've been the result of applying HornerForm[] to the polynomial.

answered May 10 '15 at 04:01

J. M.'s missing motivation

124,525
11
401
574

Why do you prefer Fold to FromDigits or Dot? Also you can drop the second argument of Fold; see: (54784) – Mr.Wizard May 10 '15 at 11:44
Elegant demonstration of a fundamental programming construct. – djp May 10 '15 at 12:30
@Mr. Wizard, re: Fold[], old habits, I guess (I still don't have a computer, much less version 10). Anyway, as I said, this is what is done internally in FromDigits[]; I thought it'd be a nice showcase for Horner. As is well-known, Horner minimizes the number of multiplications necessary for evaluating a polynomial, in contrast to an explicit monomial expansion. – J. M.'s missing motivation May 10 '15 at 14:00
Fair enough. +1 – Mr.Wizard May 10 '15 at 14:27
+1 Answering questions without a viable Mma installation is a NKC. (The C being challenge) – Dr. belisarius May 19 '15 at 01:11
@bel, it stresses my powers of imagination, surprisingly. Who'd have thought? ;) – J. M.'s missing motivation May 19 '15 at 05:53

score 5 · Accepted Answer · answered Mar 31 '13 at 03:26

5

One straightforward approach is to calculate the answer directly:

Total[{0, 1, 23, 5, 15, 0, 0, 0} x^(Range[8] - 1)]

answered Mar 31 '13 at 03:26

bill s

68,936
4
101
191

yulinlinyu · Answer 6 · 2013-03-31T03:50:48.593

3

How about this?

MapIndexed[#1*x^(#2 - 1) &, {0, 1, 23, 5, 15, 0, 0, 0}] // Total

(* {x + 23 x^2 + 5 x^3 + 15 x^4} *)

edited Mar 31 '13 at 03:50

answered Mar 31 '13 at 03:44

yulinlinyu

4,815
2
29
36

I was expecting direct command :(. This works pretty enough. – Serkan Mar 31 '13 at 03:59

Enrique Pérez Herrero · Answer 7 · 2015-08-14T15:04:54.983

0

mycoeff = {0, 1, 23, 5, 15, 0, 0, 0};
FromCoeff[lst_, x_]:=Plus@@(lst*x^(Part/@Range[Length[lst]]-1));
FromCoeff[mycoeff, x]

edited Aug 14 '15 at 15:04

answered Aug 13 '15 at 17:45

Enrique Pérez Herrero

982
1
9
14

2

I think something was copied incorrectly. Specifically Part /@ Range[Length[lst]] does not make sense. – Mr.Wizard Aug 14 '15 at 00:16
4

I guess it's working now, but Part/@ appears vestigial. Also you are pretty much duplicating bill's Accepted answer. :-/ – Mr.Wizard Aug 14 '15 at 15:08

What is the inverse of CoefficientList?

7 Answers7

Linked

Related