I want to make a parametric plot like this:
ParametricPlot[{{2 t, -10 t^2}, {t, 2 t}}, {t, 0, 2}]
I have tried the following but it doesn't work:
ParametricPlot[{{2 t, -10 t^2}, {t, 2 t}}, {{t, 0, 2}, {t, 4, 7}}]
Asked
Active
Viewed 3,251 times
3
Mr.Wizard
- 271,378
- 34
- 587
- 1,371
user1626227
- 35
- 1
- 4
3 Answers
8
ConditionalExpression[] works nicely:
ParametricPlot[{ConditionalExpression[{2 t, -10 t^2}, 0 <= t <= 2],
ConditionalExpression[{t, 2 t}, 4 <= t <= 7]}, {t, 0, 7},
AspectRatio -> 1/GoldenRatio]
J. M.'s missing motivation
- 124,525
- 11
- 401
- 574
-
J.M. are you back? :-D – Mr.Wizard Apr 03 '13 at 08:56
-
Well, back... ish. – J. M.'s missing motivation Apr 03 '13 at 08:56
-
Thank you very much for your answer, appreciate it! – user1626227 Apr 03 '13 at 09:14
-
4@user1626227 This is a fine answer, and perhaps the best one you are going to get, but as a rule I recommend that you leave more time before you Accept an answer. I usually wait 24 hours so that people in all time zones have a chance to read the question and respond if they choose, before the question appears concluded. – Mr.Wizard Apr 03 '13 at 09:16
4
Without conditional constructs, just building a list of your functions and limits
intervals = {{{2 t, -10 t^2}, {0, 2}}, {{t, 2 t}, {4, 7}}};
Show[ParametricPlot[#[[1]], Evaluate@{t, Sequence @@ #[[2]]}] & /@ intervals,
PlotRange -> Automatic, AspectRatio -> 1/GoldenRatio]
Edit
You may prefer to use \[FormalT] instead of simply t for protection against possible definitions of t elsewhere.
Edit 2
A more featured implementation, taking the color switching from @Mr's answer and forcing it to cycle so allowing to take any number of curves as argument:
f[{var_, l1_}] := Module[{style = ColorData[1] /@ Range@5},
Show[ParametricPlot[#[[1]], Evaluate@{var, Sequence @@ #[[2]]}] & /@ l1 /.
x_Line :> {First@(style = RotateRight[style]), x},
PlotRange -> Automatic, AspectRatio -> 1/GoldenRatio]]
Usage:
l = {\[FormalT],Array[{{RandomInteger[10]\[FormalT],RandomInteger[{-10,10}]
\[FormalT]^RandomReal[2]},RandomInteger[10,2]}&,10]};
f[l]
Dr. belisarius
- 115,881
- 13
- 203
- 453
-
If
tis defined this fails. I think you should add aBlockor at least a warning. (+1 nevertheless) – Mr.Wizard Apr 03 '13 at 09:13 -
@Mr.Wizard Usually I use
\[FormalT], but I rather prefer to keep the code clean here – Dr. belisarius Apr 03 '13 at 09:18 -
-
I would have used
MapThread[]instead ofMap[]myself... – J. M.'s missing motivation Apr 03 '13 at 09:41 -
@J.M. Why? I wanted the function and its associated interval clustered in one list ... – Dr. belisarius Apr 03 '13 at 09:45
-
Oh, you had the thing transposed. In that case...
ParametricPlot[#1, Prepend[#2, t] // Evaluate] & @@@ {{{2 t, -10 t^2}, {0, 2}}, {{t, 2 t}, {4, 7}}}. – J. M.'s missing motivation Apr 03 '13 at 09:49
3
For version 7 users without ConditionalExpression there is Piecewise:
ParametricPlot[
Piecewise[{{{2 t, -10 t^2}, 0 <= t <= 2}, {{t, 2 t}, 4 <= t <= 7}}], {t, 0, 7},
AspectRatio -> 1/GoldenRatio
]
To get separate styles requires additional work:
ParametricPlot[
pwSplit @ Piecewise[{{{2 t, -10 t^2}, 0 <= t <= 2}, {{t, 2 t}, 4 <= t <= 7}}],
{t, 0, 7},
AspectRatio -> 1/GoldenRatio,
PlotStyle -> {Red, Blue},
Evaluated -> True
]
pwSplit code from here. Or:
Module[{style = {Red, Blue}, i = 1},
ParametricPlot[
Piecewise[{{{2 t, -10 t^2}, 0 <= t <= 2}, {{t, 2 t}, 4 <= t <= 7}}], {t, 0, 7},
AspectRatio -> 1/GoldenRatio
] /. x_Line :> {style[[i++]], x}
]
-
1+1 How about something like
x_Line :> {First@(style = RotateRight[style]), x}in your last piece of code? – Dr. belisarius Apr 03 '13 at 09:29 -
@belisarius that's a good suggestion if one wishes for cyclic behavior. R.M would be pleased. You could also use
Mod. – Mr.Wizard Apr 03 '13 at 09:34