How I can indicate the maximum point on a curve

Question

y = r^2 (0.5) - r^3

I am trying to get maximum point on this graph from range 0 to 0.5. Can some one help??

Plot[y, {r, 0, 0.5}]

Does this answer your question? How do I determine the maximum value for a polynomial, given a range of x values? — creidhne, Dec 24 '20 at 11:41

score 4 · Accepted Answer · answered Dec 24 '20 at 11:39

4

y = r^2 (0.5) - r^3;
max = NMaximize[{y, 0 < r < .5}, r]
pt = {r /. Last@max, First@max}
Plot[y, {r, 0, 0.5}, Epilog -> {PointSize[Large], Red, Point[pt]}]

answered Dec 24 '20 at 11:39

cvgmt

72,231
4
75
133

Thanks it helped alot – Student Dec 24 '20 at 11:45

kglr · Answer 2 · 2020-12-24T19:48:30.867

4

ClearAll[f]
f[r_] := r^2 (0.5) - r^3

An alternative approach to mark the interior local maxima of a differentiable function f using MeshFunctions + Mesh + MeshStyle:

Plot[f[r], {r, 0, 0.5}, 
  MeshFunctions -> {If[f''[#] <= 0, f'[#], 1] &}, 
  Mesh -> {{0}},
  MeshStyle -> Directive[Red, PointSize[Large]]]

Normal[%] /. p_Point :> {p, Text["maximum", p[[1]], {-1, -1}]}

edited Dec 24 '20 at 19:48

answered Dec 24 '20 at 19:23

kglr

394,356
18
477
896

score 1 · Answer 3 · answered Dec 24 '20 at 13:04

1

With Callout.

y[x_] := x^2 (0.5) - x^3
max = Maximize[{y[r], 0 < r < .5}, r];
pt = {r /. Last@max, First@max};

Then

Show[
 Plot[y[r], {r, 0, .5}]
 , ListPlot[{Callout[pt, "Maximum"]}, PlotStyle -> Red]
 , PlotRange -> All
 ]

Hope this helps

answered Dec 24 '20 at 13:04

Edmund

42,267
3
51
143

Or of course set the derivative to $0$, and solve for $x$. – David G. Stork Dec 24 '20 at 19:53

How I can indicate the maximum point on a curve

3 Answers3

Linked