Plot a function over a specific domain

Question

I have a function that is defined on a specific domain for example the function $$f(x,y)=(x-0.5)*(y-0.5)$$ defined on $\Sigma$ which is the circle $(x-0.5)^2+(y-0.5)^2=0.5^2$

How to plot $f$ over $\Sigma$?

I tried something like

Plot3D[(-0.5 + x) (-0.5 + y), {x, -1, 1}, {y, -1, 1}, 
RegionFunction -> 
Function[{x, y}, 0.5^2 - 0.01 <= (x - 0.5)^2 + (y - 0.5)^2 <= 0.5^2 + 0.01]]

but I am looking for something better.

Have you considered reparametrizing in polar coordinates, and then using ParametricPlot3D[]? — J. M.'s missing motivation, Apr 25 '13 at 17:11
If you use options like PlotPoints -> 100 the results is quite nice I think. — b.gates.you.know.what, Apr 25 '13 at 17:18
@whuber Well, what I tried gave a plot with discontinuities. PlotPoints->100 seems to solve this. However it essentially gives a band around the solution, defined a parameter (in this case 0.01). Changing the parameter leads again to problems. So I am looking for a more natural way to solve this. — Jim, Apr 25 '13 at 17:37
The best solution is by @J.M. : ParametricPlot3D[{1/2 Cos[t], 1/2 Sin[t], (-1/2 + 1/2 Cos[t]) (-1/2 + 1/2 Sin[t])}, {t, 0, 2 Pi}]. — b.gates.you.know.what, Apr 25 '13 at 17:55

score 4 · Accepted Answer · answered Apr 25 '13 at 18:39

4

Try this:

Plot3D[
 (x - .5) (y - .5),                        (*  your f(x,y)       *)
 {x, 0, 1}, {y, 0, 1},
 MeshFunctions -> Function[{x, y, z},
   (x - .5)^2 + (y - .5)^2 - .5^2          (*  your Σ equation   *)
   ],
 Mesh -> {{0}},
 MeshStyle -> Red,
 PlotStyle -> None, BoundaryStyle -> None]

enter image description here

answered Apr 25 '13 at 18:39

Silvia

27,556
3
84
164

Very nice solution and it has the advantage that it works even when parametrization is difficult. – Jim Apr 25 '13 at 19:24
@Jim Thanks. In fact implicit functions are sometimes easier to use than parametric ones. Please compare to this similar question. – Silvia Apr 25 '13 at 19:28

Plot a function over a specific domain

1 Answers1