7

I want to increase the number of minor ticks in a plot, but I don't want to label them. I searched through this site and also Mathematica documentation, but I didn't find any solution yet. Could anyone please tell me how to do this.

For an example:

Plot[2*Sin[x], {x, 0, 10}, Frame -> True, 
 FrameTicks -> {True, True, False, False}, Axes -> True, 
 AxesOrigin -> {0, 0}]

I want to get 10 minor tick marks in between 0 and 1 and so on (in between major tick marks on both axis).

Here is the output plot

Community
  • 1
TMH
  • 419
  • 5
  • 12

4 Answers4

12

Here's another approach, very similar to swish's. The difference being that it should work on all sorts of plot ranges.

The idea is to define a ticks function with min_ and max_ (idea from Ticks in documentation):

ticks[min_, max_] := 
  Table[If[FractionalPart[i] == 0., {i, i, .06, Red}, {i, "", .02,Blue}], 
  {i, Floor[min], Ceiling[max], 0.1}]

Then the graph:

Plot[2*Sin[x], {x, -\[Pi], \[Pi]}, Frame -> True, 
  FrameTicks -> {ticks, ticks, False, False}, Axes -> True]

and we get:

enter image description here

we note that we could use any condition within the Table in ticks (e.g. use Switch or Which to get mid-ticks, etc.

Also, here is a version that let's the user specify ranges of noteworthy ticks directly:

r1 = Range[-3, 3, 0.2];

r2 = Range[-3, 3, 0.1];

tickfreq = 0.05;

ticks[min_, max_] := 
 Table[With[{val = Round[Abs@FractionalPart[i], 0.01]}, 
   Which[Chop[Min[Abs[r1 - val]]] == 0, {i, i, .06, Red}, 
    Chop[Min[Abs[r2 - val]]] == 0, {i, "", .04, Green}, 
    1 < 2, {i, "", .02, Blue}]], {i, Floor[min], Ceiling[max], 
   tickfreq}]

where tickfreq specifies the frequency of the blue (base-) ticks, r1 the red ticks (with labels), r2 the green additional ticks. Using then the PlotRange you specify in the comments, we get:

Plot[2*Sin[x], {x, -\[Pi], \[Pi]}, Frame -> True, 
 FrameTicks -> {ticks, ticks, False, False}, Axes -> True, 
 PlotRange -> {{-0.5, 3.5}, {-0.25, 0.3}}]

enter image description here

Alternatively, one could also use different ticks version for the axes, but I am sure you get the idea. I hope this helps.

Pinguin Dirk
  • 6,519
  • 1
  • 26
  • 36
  • Thanks a lot. I actually want to increase the height of minor ticks at middle of each major tick marks too.(minor ticks at -2.5,-1.5,-0.5,0.5,..)Could you please tell me how to do it? – TMH Apr 30 '13 at 18:05
  • If my plot range is PlotRange -> {{-0.5, 3.5}, {-0.25, 0.3}}Can I still use FractionalPart[i]? I just want to show integers in x axis, but I want to get y axis as -0.25,-0.15,-0.05,0.05,0.15,0.25. I tried to get this, but I still couldn't get it. Could you please tell me how to get it? – TMH Apr 30 '13 at 20:03
  • I tried with this, `ticks[min_, max_] := Table[Switch[Abs@FractionalPart[i*10], 0.5, {i, i, .06, Red}, 0., {i, i, .04, Green}, _, {i, "", .02, Blue}], {i, Floor[min], Ceiling[max], 0.01}]

    Plot[2*Sin[x], {x, -[Pi], [Pi]}, Frame -> True, FrameTicks -> {Automatic, ticks, False, False}, PlotRange -> {{-0.5, 3.5}, {-0.25, 0.3}}, Axes -> True]` But, I still couldn't get the expected output.

     – TMH Apr 30 '13 at 21:02
  • I am sorry for all the edits, the numerical values caused me some problems. I am using Chop now in a version that let's you specify r1 (red ticks, labeled) and r2 (green ticks), rest is blue ticks. I hope you are able to finally do your chart - good luck, I have to run! – Pinguin Dirk Apr 30 '13 at 22:40
  • Thanks a lot Pinguin for paying attention on my problem. As I told my plot range is PlotRange -> {{-0.5, 3.5}, {-0.25, 0.3}} When I run the edited code, still I couldn't get the expected out come. I tried several times. Actually, I spend all the day for this, but still I couldn't successful. – TMH May 01 '13 at 00:50
  • @THM: I updated again, I hope you see better what's going on. I explicitly stated r1, r2, tickfreq (which you should adjust to get the desired results). If it still doesn't work, we maybe should meet on chat to fix things. – Pinguin Dirk May 01 '13 at 06:54
  • I would like to come to a chat. – TMH May 01 '13 at 12:49
  • all settled in chat :) – Pinguin Dirk May 01 '13 at 13:23
  • Can I chat with you to discuss another version of this problem? – TMH May 24 '13 at 17:25
  • sure, you set up a chat room? (I still don't know how to do that) – Pinguin Dirk May 25 '13 at 08:51
  • It seems to be our times are different.I will describe my problem here. In this case, x- axis goes from 5 to 250. I want to have labels on 50,100,150,200,250 and lengths of the ticks should be same as on the previous problem. I tried with editing the previous code, but I still couldn't get it. Really appreciate your help on this. – TMH May 25 '13 at 15:28
  • ok sure: you could start with r1 = Range[0, 250, 50];r2 = Range[25, 250, 50];tickfreq = 5;; next, for the ticks, we need to remove the FractionalPart etc, so get: ticks[min_, max_] := Table[With[{val = i}, Which[Chop[Min[Abs[r1 - val]]] == 0, {i, i, .06, Red}, Chop[Min[Abs[r2 - val]]] == 0, {i, "", .04, Green}, 1 < 2, {i, "", .02, Blue}]], {i, Floor[min], Ceiling[max], tickfreq}];, finally plot: Plot[x, {x, 5, 250}, Frame -> True,FrameTicks -> {ticks, ticks, False, False}, Axes -> False, PlotRange -> {{5, 250}, {5, 250}}]. Does that yield what you wanted? – Pinguin Dirk May 26 '13 at 08:15
  • Exactly.That's what I tried.Thank you so much. You are very helpful person. – TMH May 26 '13 at 13:40
  • you are welcome! – Pinguin Dirk May 26 '13 at 14:00
4

You can always manually specify the ticks with its labels, size and style

ticks = ({#, "", {.01, .005}, Red} & /@ Range[0.1, .9, .1])~Join~Range[0, 10, 1]
Plot[2*Sin[x], {x, 0, 10}, Frame -> True, 
 FrameTicks -> {ticks, True, False, False}, Axes -> True, 
 AxesOrigin -> {0, 0}]
swish
  • 7,881
  • 26
  • 48
  • Thanks for the comment. Can I increase the height of ticks at 0.5,1,1.5,2,...and so on? – TMH Apr 30 '13 at 17:00
  • FindDivisions[] would be a very handy function here... – J. M.'s missing motivation Apr 30 '13 at 17:05
  • @swish Thanks. I actually want sub ticks for all range and to increase the height of tick marks which are located at 0,0.5,1,1.5 and 2. (I don't want to increase the height of all ticks) How to edit the above code for that purpose? – TMH Apr 30 '13 at 17:16
  • @J.M. Thanks for the comment. But, I don't know how to use it for my problem. – TMH Apr 30 '13 at 17:17
  • 2
    @TMH You can make it yourself, just specify the list of ticks you want {tick1, tick2, ...} with tickN of format {position, label, {positive_size, negative_size}, style}. – swish Apr 30 '13 at 17:24
  • @swish Could you please tell me how to join tickN which is a list of ticks inside the plot command? – TMH Apr 30 '13 at 17:29
  • @TMH Just try to analyse the code in the answer, when you will understand how it works you will answer your question. – swish Apr 30 '13 at 17:39
3

Here's a way that uses FindDivisions and the default ticks (via the undocumented ticks function Charting`ScaledTicks, which you can find all over this site):

ClearAll[myTicks, major, minor]; 
myTicks[div_, h_Symbol: Charting`ScaledTicks, 
  opts : OptionsPattern[Charting`ScaledTicks]] :=
 With[{styles = DeleteDuplicatesBy[#[[3]] &]@
      Charting`ScaledTicks[{Identity, Identity}, opts][0., 1.]},
   major[Charting`ScaledFrameTicks] := 
    Evaluate@ReplacePart[First[styles], {1 -> #, 2 -> ""}] &;
   major[Charting`ScaledTicks] := 
    Evaluate@ReplacePart[First[styles], {1 -> #, 2 -> #}] &;
   minor = Evaluate@ReplacePart[Last[styles], {1 -> #}] &;
   Flatten[
    MapThread[
     #1 /@ Flatten[#2] &,
     {{major[h], minor}, FindDivisions[{##}, div]}
     ],
    1]] &;

One can inspect Options[Charting`ScaledTicks], but "TicksLength" is the only one I can find a use for in this context. It can only be used to set the "positive" length (into the plot). The "negative" length is hard-coded to 0..

Example:

Plot[2*Sin[x], {x, 0, 10}, Frame -> True, 
 FrameTicks -> {
   {myTicks[{5, 11}, "TicksLength" -> {0.03, 0.015}], 
    myTicks[{5, 11}, Charting`ScaledFrameTicks, "TicksLength" -> {0.03, 0.015}]},
   {myTicks[{11, 11}], 
    myTicks[{11, 11}, Charting`ScaledFrameTicks]}},
 Axes -> True, AxesOrigin -> {0, 0}]

Mathematica graphics

Folks who like to hijack the system may be amused by this:

ClearAll[myTicks];
myTicks[div_, h_: Charting`ScaledTicks] := 
  Internal`InheritedBlock[{Visualization`Divisions},
    Unprotect[Visualization`Divisions];
    Visualization`Divisions[{##}, {6, 6}, 10, ScalingFunctions -> {Identity, Identity}] := 
     FindDivisions[{##}, div];
    Protect[Visualization`Divisions];
    h[{Identity, Identity}][##]
    ] &;

It works similar to the above, but without the options. It basically allows you to set the tick divisions from the hard-coded default {6, 6} to whatever you like.

Community
  • 1
Michael E2
  • 235,386
  • 17
  • 334
  • 747
1

We can (1) use the optional third argument of Charting`ScaledTicks[..] to specify the number of major and minor ticks (2) use the same ticks spec for left and right (and bottom and top) frames, (3) hide the labels in top and right frames using FontOpacity -> 0 as the FrameStyle:

Plot[2*Sin[x], {x, 0, 10}, Frame -> True,
  FrameStyle -> {{Automatic, FontOpacity -> 0}, {Automatic, FontOpacity -> 0}}, 
  FrameTicks -> {{#, #} & @ (Charting`ScaledTicks[{Identity, Identity}, 
      "TicksLength" -> {0.03, 0.015}][##, {5,  11}] &), 
    {#, #} & @ (Charting`ScaledTicks[{Identity, Identity}, 
      "TicksLength" -> {0.03, 0.015}][##, {11, 11}] &)}, 
  Axes -> True, AxesOrigin -> {0, 0}]

enter image description here

kglr
  • 394,356
  • 18
  • 477
  • 896