Dropping list elements that are members of other lists

Question

I have a set:

$$A=\{\{1,2,3\},\{1,3,2\},\{2,1,3\},\{2,3,1\},\{3,1,2\},\{3,2,1\}\}$$

I want to drop elements found in sets B and C from A.

$$B=\{\{1,3,2\},\{2,1,3\}\}$$ $$C=\{\{3,1,2\},\{3,2,1\}\}$$ How can I do this?

My attempts:

A = {{1, 2, 3}, {1, 3, 2}, {2, 1, 3}, {2, 3, 1}, {3, 1, 2}, {3, 2, 1}}
B = {{1, 3, 2}, {2, 1, 3}}
C = {{3, 1, 2}, {3, 2, 1}}
DeleteCases[A, B]

It does not give the desired result I had to write it like this

DeleteCases[A, {1, 3, 2}]

I also tried to do it iteratively but it did not work.

Unless I'm missing something, this is exactly what Complement does — Lukas Lang, May 10 '22 at 20:05
Please start variable names with lowercase letters. Names starting with uppercase letters are used by the system. — Syed, May 10 '22 at 20:18
Here is one method. `In[113]:= aA = {{1, 2, 3}, {1, 3, 2}, {2, 1, 3}, {2, 3, 1}, {3, 1, 2}, {3, 2, 1}}; bB = {{1, 3, 2}, {2, 1, 3}}; cC = {{3, 1, 2}, {3, 2, 1}}; DeleteCases[aA, Apply[Alternatives, Join[bB, cC]]]
Out[116]= {{1, 2, 3}, {2, 3, 1}}` — Daniel Lichtblau, May 10 '22 at 20:46
Or wait for version 13.1 and do this. `In[4]:= DeleteElements[aA, Join[bB, cC]]
Out[4]= {{1, 2, 3}, {2, 3, 1}}` — Daniel Lichtblau, May 10 '22 at 20:48
One potential (documented) problem with Complement is that the output is sorted. See Complement[] changes order of elements? and How to Delete Elements from List1 appearing in List2? and UnsortedComplement, a resource function that "Delete the elements of some lists from a list x without changing either the order of x or the multiplicities of its elements" by George Beck — user1066, May 11 '22 at 09:25
Compare DeleteCases[new, Alternatives@@Join[b,c]] with Complement[new, b,c], where new=Reverse@a — user1066, May 11 '22 at 09:44

score 6 · Answer 1 · answered May 10 '22 at 20:16

This is the exact use case for Complement:

a = {{1, 2, 3}, {1, 3, 2}, {2, 1, 3}, {2, 3, 1}, {3, 1, 2}, {3, 2, 1}};
b = {{1, 3, 2}, {2, 1, 3}};
c = {{3, 1, 2}, {3, 2, 1}};
Complement[a, b, c]
(* Out: {{1, 2, 3}, {2, 3, 1}} *)

As an aside, do not use variable names that start with capital letters because those have customarily been reserved for built in functions. In particular, avoid using single-letter uppercase variable names like A, B, C (used as a constant in equation solving), I (the imaginary unit), E (the base of natural logarithms), K, and more: many have built-in meaning which can lead to odd behavior and hard-to-trace bugs.

Syed · Answer 2 · 2022-05-10T20:22:33.587

5

Using DeleteCases:

This will delete any x such that x is a member of either b or c.

DeleteCases[a, x_ /; MemberQ[b, x] || MemberQ[c, x]]

Using Complement:

Complement[Complement[a, b], c]

or better still:

Fold[Complement, a, {b, c}]

Result:

{{1, 2, 3}, {2, 3, 1}}

edited May 10 '22 at 20:22

answered May 10 '22 at 20:17

Syed

52,495
4
30
85

3

... or better still: Complement[a, b, c]. There is no need to apply the function twice, or to fold it over the input. – MarcoB May 11 '22 at 01:38

score 3 · Answer 3 · answered May 10 '22 at 19:58

One possibility to achieve this is to join all sets to be replaced and then successively delete them (note also, do not use capitalized variable names, they are reserved for the system):

a = {{1, 2, 3}, {1, 3, 2}, {2, 1, 3}, {2, 3, 1}, {3, 1, 2}, {3, 2, 1}};
b = {{1, 3, 2}, {2, 1, 3}};
c = {{3, 1, 2}, {3, 2, 1}};

We set tmp to a and then delete the subsets:

tmp = a;
Scan[(tmp = DeleteCases[tmp, #]) &, Join[b, c], 1];
tmp
(* {{1, 2, 3}, {2, 3, 1}} *)

Dropping list elements that are members of other lists

3 Answers3