Complement[] changes order of elements?

Question

Consider this example:

Complement[{a, y, c, d, e}, {a, c}, {d}]
(*{e, y}*)

However, I was expecting the result to be:

(*{y,e}*)

Why did Complement[] reorder the resulting list?

Any idea how to get the desired results (list with elements in their original order), using Complement[]?

Related, possibly duplicate? http://mathematica.stackexchange.com/q/1290/862 — Simon Woods, Sep 10 '14 at 20:04
may be not related but instead easily found in the documentation. I was look for explanations why Complement sorts the results (the documentation says it is stored internally). — Basheer Algohi, Sep 10 '14 at 20:12
@Mr.Wizard, it was late and I was too lazy to properly check if both questions were asking the same thing, so I just posted the link in case anyone else was looking for it. As there are still no close votes I guess the community consensus is that it's not a duplicate. — Simon Woods, Sep 11 '14 at 09:20

score 8 · Accepted Answer · answered Sep 10 '14 at 20:00

8

It uses sorting internally (as documented, actually). For unsorted, could do as below.

unsortedComplement[l1_, l2_] := Reap[Module[
    {remove},
    Map[(remove[#] = True) &, l2];
    Map[If[TrueQ[remove[#]], Null, Sow[#]] &, l1];
    Clear[remove];
    ]][[2, 1]]

unsortedComplement[{1, 3, 2, 8, 5}, {3, 6}]

(* Out[78]= {1, 2, 8, 5} *)

Extending to more lists is straightforward.enter code here

answered Sep 10 '14 at 20:00

Daniel Lichtblau

58,970
2
101
199

Thanks. there are so many other ways to get the desired results. I was just wondering if there is any way to tell Complement to unsort the result. perhaps I should have read the document carefully. thanks for the answer – Basheer Algohi Sep 10 '14 at 20:08

score 7 · Answer 2 · answered Sep 10 '14 at 19:54

7

This should get you the desired result:

 Select[{a, y, c, d, e}, MemberQ[Union[{a, c}, {d}], #] == False &]

{y, e}

answered Sep 10 '14 at 19:54

paw

5,650
23
31

Dr. belisarius · Answer 3 · 2014-09-10T20:38:57.647

6

If you want to stick with Complement[]

l = {a, y, c, d, e};;
l[[Sort[Complement[l, {a, c}, {d}] /. Thread[l -> Range@Length@l]]]]
(*{y, e}*)

or

SortBy[Complement[l, {a, c}, {d}], Position[l, #] &]
(*{y, e}*)

edited Sep 10 '14 at 20:38

answered Sep 10 '14 at 20:27

Dr. belisarius

115,881
13
203
453

score 2 · Answer 4 · answered Dec 24 '23 at 00:08

2

la = {a, y, c, d, e};
lb = {a, c};
lc = {d};

Since V 13.1 we have DeleteElements and UniqueElements

DeleteElements[la, Join[lb, lc]]

{y, e}

UniqueElements[{la, lb, lc}]

{{y, e}, {}, {}}

First[%]

{y, e}

answered Dec 24 '23 at 00:08

eldo

67,911
5
60
168

score 2 · Answer 5 · answered Dec 24 '23 at 00:12

2

Using DeleteCases:

DeleteCases[{a, y, c, d, e}, Alternatives @@ Union @@ {{a, c}, {d}}]
({y, e})

answered Dec 24 '23 at 00:12

E. Chan-López

23,117
3
21
44

Complement[] changes order of elements?

5 Answers5

Linked