From a list to a list of rules

Question

Starting from these two lists,

var = {a, b, c} 
values = {{1, 2, 3}, {4, 5, 6}, {7, 8 , 9}}

how can I generate a list of rules?

rules = {{a -> 1, b -> 2, c -> 3}, {a -> 4, b -> 5, c -> 6}, {a -> 7, b -> 8, c -> 9}}

This is how far I have got

In: {{a, b, c}, {1, 2, 3}} // Transpose
In: Rule @@@ %
Out: {{a, 1}, {b, 2}, {c, 3}}
Out: {a -> 1, b -> 2, c -> 3}

Szabolcs · Accepted Answer · 2012-03-16T10:06:20.833

34

Another way:

Thread[var -> #] & /@ values

edited Mar 16 '12 at 10:06

answered Mar 16 '12 at 08:49

Szabolcs

234,956
30
623
1,263

5

Cleaner: Thread[var -> #] & /@ values – Mr.Wizard Mar 16 '12 at 09:51
@Mr.Wizard Okay. – Szabolcs Mar 16 '12 at 10:06

Mr.Wizard · Answer 2 · 2012-03-16T12:29:00.040

27

I propose using Inner:

Inner[Rule, var, values\[Transpose], List]

This is faster than other methods presented:

SetAttributes[timeAvg, HoldFirst]

timeAvg[func_] := 
  Do[If[# > 0.3, Return[#/5^i]] & @@ Timing @ Do[func, {5^i}], {i, 0, 15}]

var = Range@70;
values = Array[Times, {500, 70}];

Inner[Rule, var, values\[Transpose], List]; // timeAvg
Map[Rule @@@ Transpose[{var, #}] &, values]; // timeAvg
Thread[var -> #] & /@ values; // timeAvg
MapThread[Rule, {var, #}] & /@ values; // timeAvg

edited Mar 16 '12 at 12:29

answered Mar 16 '12 at 09:23

Mr.Wizard

271,378
34
587
1,371

Would you mind editing in the definition of timeAvg? – Yves Klett Mar 16 '12 at 09:25
@Yves I put at link at the bottom; is that good enough? – Mr.Wizard Mar 16 '12 at 09:26
1

Sure! Perhaps for the casual sloppy Paste&Evaluate user (i.e. me) actually putting it in would be more convenient. – Yves Klett Mar 16 '12 at 09:32
1

@Yves done as requested. – Mr.Wizard Mar 16 '12 at 09:44
Still another possibility: Inner[#2 -> #1 &, values, var, List] – J. M.'s missing motivation Oct 27 '12 at 02:08
@J.M. While pleasingly concise that is unfortunately about 2X slower. IIRC I considered that exact form before writing my answer. – Mr.Wizard Oct 29 '12 at 02:29
Interesting. I would have thought skipping the Transpose[] would be a good idea. – J. M.'s missing motivation Oct 29 '12 at 02:36

score 15 · Answer 3 · answered Mar 16 '12 at 08:45

15

Just do a map on the values, like this:

var = {a, b, c}
values = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}
Map[Rule @@@ Transpose[{var, #}] &, values]

This is the output: {{a -> 1, b -> 2, c -> 3}, {a -> 4, b -> 5, c -> 6}, {a -> 7, b -> 8, c -> 9}}

(In your question you have c->5, but I'm assuming this is a mistake:)

answered Mar 16 '12 at 08:45

Ajasja

13,634
2
46
104

1

I would use Thread[var -> #]&, or Thread[ Rule[ var, # ]]&, if you prefer, as the function being mapped. It accomplishes the same thing with less code. I'd even be tempted to rewrite it as Thread[var -> #]& /@ values to take advantage of the shorthand notation. – rcollyer Mar 16 '12 at 19:19

score 14 · Answer 4 · answered Mar 16 '12 at 08:59

14

Another alternative:

MapThread[#1 -> #2 &, {var, #}] & /@ values

or, equivalently

MapThread[Rule, {var, #}] & /@ values

answered Mar 16 '12 at 08:59

Niki Estner

36,101
3
92
152

score 6 · Answer 5 · answered Oct 26 '12 at 21:11

6

Just for fun, another alternative using Outer:

Flatten[Outer[Thread[#1 -> #2] &, {var}, values, 1], 1]

answered Oct 26 '12 at 21:11

Murta

26,275
6
76
166

yode · Answer 6 · 2016-03-31T07:36:51.917

3

AssociationThread[var, #] & /@ values // Normal

{{a->1,b->2,c->3},{a->4,b->5,c->6},{a->7,b->8,c->9}}

Just for record

GeneralUtilities`AssociatePairs[Transpose[{var, #}]] & /@ values // Normal

{{a->1,b->2,c->3},{a->4,b->5,c->6},{a->7,b->8,c->9}}

edited Mar 31 '16 at 07:36

answered Mar 13 '16 at 19:14

yode

26,686
4
62
167

From a list to a list of rules

6 Answers6

Linked

Related