Expanding lists with split strings

Question

I've got data of the type:

list = {"Class","MW","10 - 11"}

which I would like to split into a number of lists based on the number of characters in the second list element. In the above case, the desired output would be:

newlists = {{"Class","M","10-11"},{"Class","W","10-11"}}

StringSplit[list[[2]],""] gets me in the right direction (the string I want to split will always be in the same position in the list); however, I don't know how to thread this new sublist through the original list.

Guessing where you're going with this, you might want to look at Generating schedules/timetables in Mathematica — rm -rf, Oct 02 '13 at 15:56
@rm-rf Wish I had posted this question before writing the grid layout code... — bobthechemist, Oct 02 '13 at 17:50
@cormullion I found it ironic that a 10k+ rep'er was referring to others as 'experts'. I wonder if SE gives us a way to see what the rep was when a person answered the question. — bobthechemist, Oct 02 '13 at 19:59
@bobthechemist You can find a user's network profile from their site profile. From there, the reputation tab has a nice plot that you can use to quickly find out what the user's rep was on a given date. — rm -rf, Oct 02 '13 at 20:24

score 11 · Accepted Answer · answered Oct 02 '13 at 15:54

11

Here's how you can thread them:

newlists = Thread[{#, Characters@#2, ##3}] & @@ list
(* {{"Class", "M", "10 - 11"}, {"Class", "W", "10 - 11"}} *)

answered Oct 02 '13 at 15:54

rm -rf

88,781
21
293
472

Is there a less ambiguous way to map this command over a list of list: Thread[{#, Characters@#2, ##3}]& @@ # & /@ multilists? I don't know how concerned I should be about nested pure functions. – bobthechemist Oct 02 '13 at 18:02
1

@bobthechemist Thread[{#, Characters@#2, ##3}] & @@@ multilists you can also add // Flatten[#, 1] & if you need. – Kuba Oct 02 '13 at 19:08

score 7 · Answer 2 · answered Oct 02 '13 at 18:33

7

Here is an approach that doesn't use threading.

data = {"Class", "MW", "10 - 11"};
{a, b, c} = data;
new = {a, #, c} & /@ Characters @ b

{{"Class", "M", "10 - 11"}, {"Class", "W", "10 - 11"}}

answered Oct 02 '13 at 18:33

m_goldberg

107,779
16
103
257

score 3 · Answer 3 · answered Jan 07 '18 at 01:24

3

Distribute[MapAt[Characters, list, {2}], List] (* or *)
Distribute[MapAt[StringSplit[#, ""]&, list, {2}], List]

{{"Class", "M", "10 - 11"}, {"Class", "W", "10 - 11"}}

answered Jan 07 '18 at 01:24

kglr

394,356
18
477
896

score 2 · Answer 4 · answered Oct 02 '13 at 21:35

Maybe not handy but interesting way to apply automatic threading:

SetAttributes[h, Listable];
h @@ MapAt[Characters, list, {2}] /. h -> List

{{"Class", "M", "10 - 11"}, {"Class", "W", "10 - 11"}}

multilist = {{"Class", "MW", "10 - 11"}, {"Class", "MK", "10 - 11"}}

h @@@ MapAt[Characters, multilist, {All, 2}] /. h -> List

{{{"Class", "M", "10 - 11"}, {"Class", "W", "10 - 11"}}, 
   {{"Class", "M", "10 - 11"}, {"Class", "K", "10 - 11"}}}

score 2 · Answer 5 · answered Oct 03 '13 at 13:05

2

fun[u_] := Module[{dow},
  dow = Characters[#[[2]]] &@u;
  ReplacePart[u, 2 -> #] & /@ dow]

answered Oct 03 '13 at 13:05

ubpdqn

60,617
3
59
148

Expanding lists with split strings

5 Answers5