X label in GraphicsColumn is cut off

Question

I'm trying to use GraphicsColumn to plot two curves with very different ranges. for example,

GraphicsColumn[{Plot[Sin[x], {x, 0, 10}, PlotRange -> All, 
   AspectRatio -> 0.3, Frame -> True, Axes -> False, 
   ImageMargins -> 20], 
  Plot[Cos[x], {x, 0, 10}, PlotRange -> All, AspectRatio -> 0.3, 
   Frame -> True, Axes -> False, ImageMargins -> 20]}, 
 Epilog -> {Text["Frequency", {Center, Bottom}], 
   Rotate[Text["Power", {0.5, Center}], 90 Degree]}]

But the x label is not displayed properly, i.e., it is cut by the edge of the graph.

enter image description here

How to improve it?

A related question is: Cropped pdf file after export – Jens Jun 26 '12 at 05:35 — Jens, Jun 26 '12 at 05:35

Vitaliy Kaurov · Accepted Answer · 2012-06-26T06:06:19.570

10

PlotRangePadding option can give you more space around your graphics objects.

GraphicsColumn[{Plot[Sin[x], {x, 0, 10}, PlotRange -> All, 
   AspectRatio -> 0.3, Frame -> True, Axes -> False, 
   ImageMargins -> 20], 
  Plot[Cos[x], {x, 0, 100}, PlotRange -> All, AspectRatio -> 0.3, 
   Frame -> True, Axes -> False, ImageMargins -> 20]}, Epilog -> 
  Style[{Text["Frequency", Scaled@{.5, .02}], 
    Rotate[Text["Power", Scaled@{.03, .5}], 90 Degree]}, 14, 
   FontFamily -> "Helvetica"], PlotRangePadding -> {0, 70}, 
 ImageSize -> 500]

enter image description here

edited Jun 26 '12 at 06:06

answered Jun 26 '12 at 04:02

Vitaliy Kaurov

73,078
9
204
355

Thank you. You've known so much about plot! – yulinlinyu Jun 26 '12 at 04:08
@Mr.Wizard Just checked. Image corresponds to the code. M.8.0.4, win7. – Vitaliy Kaurov Jun 26 '12 at 05:57
@Mr.Wizard Maybe something changed for absolute coordinate specs from v7 to v8. I changed code to scaled coordinates. Could you check if this helps? – Vitaliy Kaurov Jun 26 '12 at 06:07
Confirmed to work. +1 – Mr.Wizard Jun 26 '12 at 06:19

score 6 · Answer 2 · answered Jun 26 '12 at 05:34

An alternative using Labeled:

Labeled[
 GraphicsColumn[{
   Plot[Sin[x], {x, 0, 10}, PlotRange -> All, AspectRatio -> 0.3,
    Frame -> True, Axes -> False, ImageMargins -> 0], 
   Plot[Cos[x], {x, 0, 100}, PlotRange -> All, AspectRatio -> 0.3, 
    Frame -> True, Axes -> False, ImageMargins -> 0]}, 
   Alignment -> Left], 
 {"Frequency", "Power"}, {Bottom, Left}, 
 RotateLabel -> True, 
 LabelStyle -> Directive[Bold, FontFamily -> "Helvetica"], 
 FrameMargins -> 0, ImageMargins -> 10]

enter image description here

X label in GraphicsColumn is cut off

2 Answers2

Linked