PlotLegends for ListPlot with more than 15 curves?

Question

fixed in 10.1 (windows)

I'm running into trouble getting the right PlotMarkers in the legend of a ListPlot of many curves. Simple example:

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], Joined -> True, 
    PlotMarkers -> {Automatic, Large}, PlotLegends -> Range[20]]

produces:

labeled plot

The legend has the right colors for all curves, but after the fifteenth curve, the markers reset instead of continuing to cycle as they do in the actual plot. If I use PlotLegends->Automatic instead of PlotLegends->Range[20], the legend simply stops with the fifteenth curve.

Any idea what might be going on here?

EDIT: Thanks everybody! There are several different good solutions below. A couple people suggested that this is a bug, so I've added that tag.

Thanks for the Accept. I included code for the first two examples which I had forgotten. Also, consider using ListLinePlot instead of ListPlot and Joined -> True -- it doesn't help this particular problem but it is shorter and seems to be better supported, e.g. (58808) — Mr.Wizard, Mar 11 '15 at 21:21
@Mr.Wizard: Good point about ListLinePlot. I'm in the habit of using Joined->True because it makes it easy to switch among ListPlot, ListLogPlot, ListLogLinearPlot, and ListLogLogPlot, but is there a better way to do this with just ListLinePlot? I guess ScalingFunctions is an (undocumented) option. — Daniel Weissman, Mar 12 '15 at 01:00
Good point yourself; I think Joined -> True is the simplest method for the log plot functionality. — Mr.Wizard, Mar 13 '15 at 05:36

score 9 · Accepted Answer · edited Apr 13 '17 at 12:55

I believe this can be considered a bug, but it is also related to the (IMHO) non-bug behavior of automatic styling described in PlotLegends won't generate automatically more than 15 labels in v10. We see that if we use PlotLegends -> Automatic the number of legends is limited to the number of styles:

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], Joined -> True, 
 PlotStyle -> ColorData[97] ~Array~ 13, PlotMarkers -> {Automatic, Large}, 
 PlotLegends -> Automatic]

enter image description here

In the main plot, and in the legend up to the number colors in PlotStyle, the plot markers are cycled five solid and five outlined. However in the legend this cycle resets after the number of styles is expended. For example it starts again five solid from 14 if we force additional legend items:

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], Joined -> True, 
 PlotStyle -> ColorData[97] ~Array~ 13, PlotMarkers -> {Automatic, Large}, 
 PlotLegends -> Range[20]]

enter image description here

The fact that the markers in the plot and legend get "out of sync" appears to be a fault, but understanding it we can solve the problem by providing a sufficient number of styles:

enough = ColorData[#, "ColorList"] & /@ Join[97, 13];

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], Joined -> True, 
 PlotMarkers -> {Automatic, Large}, PlotLegends -> Range[20], PlotStyle -> enough]

enter image description here

Alternatively if you make sure that the number of styles is a multiple of ten it will align but there will undesirably be repeats in the legend.

score 5 · Answer 2 · edited Apr 13 '17 at 12:56

PlotMarkers are passed to the legends via the LegendMarkers option. Here it looks like only 15 markers are being passed in, e.g.

In[3]:= plot = ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], 
   Joined -> True, PlotMarkers -> {Automatic, Large}, 
   PlotLegends -> Range[20]];

In[4]:= Cases[plot, HoldPattern[LegendMarkers -> l_] :> l, -1]

Out[4]= {{{"\[FilledCircle]", Large}, {"\[FilledSquare]", Large}, 
 {"\[FilledDiamond]", Large}, {"\[FilledUpTriangle]", Large}, 
 {"\[FilledDownTriangle]", Large}, {"\[EmptyCircle]", Large}, 
 {"\[EmptySquare]", Large}, {"\[EmptyDiamond]", Large}, 
 {"\[EmptyUpTriangle]", Large}, {"\[EmptyDownTriangle]", Large}, 
 {"\[FilledCircle]", Large}, {"\[FilledSquare]", Large}, 
 {"\[FilledDiamond]", Large}, {"\[FilledUpTriangle]", Large}, 
 {"\[FilledDownTriangle]", Large}}}

So, while Mr.Wizard's suggestion is the reliably correct method, I would suggest something different. LegendMarkers is cyclic in application, so you could simply reduce the number of markers used to 10, e.g.

plot /. HoldPattern[LegendMarkers -> l_] :> (LegendMarkers -> l[[;; 10]])

enter image description here

kglr · Answer 3 · 2015-03-11T01:00:01.493

3

markers = {#, Large} & /@ PadRight[#, 20, #] &@ Graphics`PlotMarkers[][[All, 1]];

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], Joined -> True, 
    PlotMarkers -> markers, PlotLegends ->LineLegend[Range[20], LegendMarkers ->  markers]]

edited Mar 11 '15 at 01:00

answered Mar 11 '15 at 00:51

kglr

394,356
18
477
896

score 2 · Answer 4 · answered Mar 11 '15 at 00:20

2

It works fine in MMA 9:

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], Joined -> True,
  PlotMarkers -> Automatic, PlotLegends -> LineLegend[Range[20]]]

enter image description here

It looks like a bug in MMA v10

answered Mar 11 '15 at 00:20

Basheer Algohi

19,917
1
31
78

score 2 · Answer 5 · answered Apr 02 '15 at 06:35

2

This has been fixed in 10.1

Mathematica graphics

code

ListPlot[Table[{j, i}, {i, Range[20]}, {j, Range[3]}], 
Joined -> True, PlotMarkers -> {Automatic, Large}, PlotLegends -> Range[20]]

answered Apr 02 '15 at 06:35

Nasser

143,286
11
154
359

David G. Stork · Answer 6 · 2015-03-11T00:28:22.053

1

Try making a list of all the PlotMarkers:

 ListPlot[
     Table[{j, i}, {i, Range[20]}, {j, Range[3]}],
     Joined -> True,
     PlotStyle -> Table[Hue[i/20], {i, 20}],
     PlotMarkers -> (Text[Style[#, 16]] & /@ CharacterRange["a", "z"]),
     PlotLegends -> Range[20]
         ]

enter image description here

I suspect that the default list of PlotMarkers has only 15 entries (in v. 10.0.0).

edited Mar 11 '15 at 00:28

answered Mar 10 '15 at 23:15

David G. Stork

41,180
3
34
96

1

This doesn't seem to address the OP's problem. The 20 plot markers on the plot itself are all distinguishable. – m_goldberg Mar 10 '15 at 23:45

PlotLegends for ListPlot with more than 15 curves?

6 Answers6