How to map Unevaluated over a list

Question

I have a list {a1, a2, ...... , an}, in which all as have been initialized to a number. I want to get:

 {Unevaluated[a1], Unevaluated[a2], ...... , Unevaluated[an]}

Is there a simple way to achieve this using Map, without getting a list of Unevaluated[value of ai]?

score 10 · Answer 1 · answered May 22 '15 at 16:30

10

unevaluatedF = Function[{x}, Unevaluated@x, {HoldFirst, Listable}];

{a1, a2, a3} = {1, 2, 3};
unevaluatedF@{a1, a2, a3}

{Unevaluated[a1], Unevaluated[a2], Unevaluated[a3]}

answered May 22 '15 at 16:30

kglr

score 7 · Answer 2 · answered May 22 '15 at 17:13

7

you can try also:

{a1, a2, a3} = {1, 2, 3};
Unevaluated /@ Unevaluated@{a1, a2, a3}

(*{Unevaluated[a1], Unevaluated[a2], Unevaluated[a3]}*)

answered May 22 '15 at 17:13

Basheer Algohi

Mr.Wizard · Answer 3 · 2015-05-22T17:43:12.013

3

First a link to a presentation everyone should read:

Now some additional methods:

List @@ Unevaluated /@ Hold[a1, a2, a3]

Unevaluated /@ Unevaluated @ {a1, a2, a3}

More contrived:

Unevaluated @@@ Thread @ Hold[{a1, a2, a3}]

{Unevaluated /@ Hold[a1, a2, a3]} // ReleaseHold

Delete[{Unevaluated /@ Hold[a1, a2, a3]}, {1, 0}]

edited May 22 '15 at 17:43

answered May 22 '15 at 17:13

Mr.Wizard

score 0 · Answer 4 · answered May 22 '15 at 16:25

0

Is this what you're seeking?

Unevaluated /@ {a1, a2, a3, a4}

(*

{Unevaluated[a1], Unevaluated[a2], Unevaluated[a3], Unevaluated[a4]}

*)

answered May 22 '15 at 16:25

David G. Stork

1

Not really, a1, a2, a3 are all initialized, so if a1 = 10, I will get Unevaluated[10], which could not be used in Set – Yituo May 22 '15 at 16:29

4 Answers4