2D Fourier transform

Question

I want to calculate the 2D Fourier transformation of a circular shaped aperture, but Mathematica won't finish the calculation:

h[x_, y_] := UnitBox[Sqrt[x^2 + y^2]]
Plot3D[FourierTransform[h[x, y], {x, y}, {k1, k2}], {k1, -5, 5}, {k2, -5, 5}]

So I tried to use the numerical NFourierTransform, but it showed me just an empty plot.

Needs["FourierSeries`"]
Plot3D[NFourierTransform[h[x, y], {x, y}, {k1, k2}], 
  {k1, -3, 3}, {k2, -3, 3}, 
  PlotRange -> All]

Does somebody know how I can calculate the Fourier transform of a circular aperture in a reasonable amount of time?

Sorry, I tried different versions of the UnitBox and forgot to change the function. I edited my Question. — lIlIIIllIIIllII, Aug 25 '15 at 13:59
Presumably there are some imaginary numbers in the result which is why you get an empty image. Either take Abs of the Fourier transform, or look at the real and imaginary parts separately. You could also create an image of the aperture ap=Table[h[i,j],{i,-5,5,10/99},{j,-5,5,10/99}] and do the discrete transform ArrayPlot[Abs@Fourier@ap] or something. — N.J.Evans, Aug 25 '15 at 14:23
The reason why NFourierTransform gives you an empty box is that it can only handle one-dimensional integrals. For a more robust numerical approach, you may want to look at 2D Fourier transform of a few (4) disjoint discs on a plane — Jens, Aug 25 '15 at 23:34

score 6 · Answer 1 · answered Aug 26 '15 at 00:29

To get the correct result for the 2D Fourier transform of a function which doesn't factor in Cartesian coordinates, it's usually necessary to give Mathematica some assistance as to the best choice of coordinates.

In the circular case, that of course means we should use polar coordinates:

Clear[k];
airy[k_] = 
 1/(2 Pi)
   Integrate[
   r Exp[I k r Cos[ϕ]], {r, 0, 1}, {ϕ, -Pi, Pi}]

(* ==> BesselJ[1, k]/k *)

Plot[airy[k], {k, -40, 40}, PlotRange -> All]

This is the famous Airy diffraction pattern of a circular aperture (when squared to get the intensity).

In setting up the integral for the Fourier transform, I used the fact that the expected result will depend only on the magnitude and not on the direction of the wave vector, so that you can choose the direction of $\vec{k}$ as the x axis for the polar integral.

+1 I deleted my answer.You're right, of course (I forgot the Jacobian) — Dr. belisarius, Aug 26 '15 at 02:12

2D Fourier transform

1 Answers1