How to customize color scheme to mimic that in Origin?

Question

Origin is a software for plotting.

The standard color scheme used by Origin is

So how do I mimic this color scheme in Mathematica, so that we can use it in DensityPlot to achieve the same appearance that will be produced by Origin?

edit

C. E. already provided a color bar that resembles the one in Origin.

To use it in ListDensityPlot, there is one more step needed to specify the ColorFunction properly:

DensityPlot[Sin[x] Sin[y], {x, -4, 4}, {y, -3, 3}, 
 ColorFunction -> (Hue[1 - (2 #/3 + 1/3)] &), 
 PlotLegends -> Automatic, PlotPoints -> 50]

Notice that I use 1/3, because in Origin, the color runs from blue to red. Red corresponds to Hue[1] and blue corresponds to Hue[1/3]. This can be seen from ColorConvert[Hue[1/3], RGBColor] // FullForm. (Thanks to J.M. for letting me know about ColorConvert)

The above code gives

It's very similar to Hue: BarLegend[{Hue[1 - #] &, {0.3, 1}}] — C. E., Dec 05 '15 at 16:27
@Pickett Bravo! indeed. Make it answer? or is it a duplicate? or just too trivial : ) — matheorem, Dec 05 '15 at 16:34
Have a look at BarLegend[{Hue[2 (1 - Rescale[#, {-1, 1}])/3] &, {-1, 1}}]. — J. M.'s missing motivation, Dec 10 '15 at 05:00
@J.M. Thank you. A question: How to know the RGB values of for example Hue[0.33]? — matheorem, Dec 10 '15 at 05:43
You can use ColorConvert[] to convert colors in any other format to RGB; e.g. ColorConvert[Hue[1/3], RGBColor]. — J. M.'s missing motivation, Dec 10 '15 at 06:07
@J.M. Thank you very much ! I have corrected my post. Now it should be exactly the same as Origin — matheorem, Dec 10 '15 at 06:43
This is pretty similar to the Jet color map from MATLAB. Jet goes a little darker in the red and blue than the examples using Hue — Jason B., Dec 10 '15 at 08:58
The Hue[] version is preferable, but otherwise, here's a Blend[] version: Blend[{Blue, Cyan, Green, Yellow, Red}, #] &. — J. M.'s missing motivation, Dec 10 '15 at 15:08
@J.M. Sorry for the late reply. This is great! Make it an answer? : ) — matheorem, Dec 12 '15 at 13:52

score 10 · Accepted Answer · answered Dec 05 '15 at 16:56

10

It is basically a reversed Hue that's been clipped off. In the image to the left below you see all of the values of Hue next to one that I cut off by picking a value (0.3) that seemed right. That value could be calculated more rigorously by looking at the color peaks and the distances between them in the Origin bar legend.

Row[{
  BarLegend[{Hue[1 - #] &, {0, 1}}],
  BarLegend[{Hue[1 - #] &, {0.3, 1}}]
  }]

Mathematica graphics

answered Dec 05 '15 at 16:56

C. E.

70,533
6
140
264

Since Hue[2/3] is actually Blue after RGB conversion, your second line should be something like BarLegend[{Hue[2 (1 - #)/3] &, {0, 1}}]. – J. M.'s missing motivation Dec 10 '15 at 04:58

score 6 · Answer 2 · answered Dec 12 '15 at 17:53

By request:

Altho I prefer the Hue[] formulation:

originColorFunction = Hue[2 (1 - #)/3] &;

one can also choose to implement this in terms of Blend[]:

originColorFunction2 = Blend[{Blue, Cyan, Green, Yellow, Red}, #] &;

To see why this works, recall that in the HSB system, the color cycle proceeds in the sequence Red, Yellow, Green, Cyan, Blue, Magenta, and finally back to Red, with linear interpolation of colors in between:

ColorConvert[Hue /@ (Range[0, 5]/6), RGBColor]
   {RGBColor[1., 0., 0.], RGBColor[1., 1., 0.], RGBColor[0., 1., 0.],
    RGBColor[0., 1., 1.], RGBColor[0., 0., 1.], RGBColor[1., 0., 1.]}

and since the Origin color function has Magenta dropped, as well as the colors being reversed, the simple linear interpolation with Blend[] will produce the exact same color sequence.

(N.B. this is also the color scheme used by the DLMF.) – J. M.'s missing motivation Mar 17 '18 at 13:01 — J. M.'s missing motivation, Mar 17 '18 at 13:01

How to customize color scheme to mimic that in Origin?

2 Answers2

Linked

Related