Variable naming changes everything

Question

Bug fixed in 10.0.0

I am having a rather unusual problem I do not understand with Mathematica where renaming one of the variables of my function causes the function to stop "working". Here is the example of the code doing what it should:

F[t_, a_, b_, l_] = x[t] /. First@
DSolve[{x'[t] == a*x[t]*(1 - (x[t]/b)) - l*x[t], x[0] == 0.4}, x[t], t];

Changing one variable name causes the code to throw out error messages. The non-working code is

F[t_, r_, b_, l_] = x[t] /. First@ DSolve[{x'[t] == r*x[t]*(1 -
(x[t]/b)) - l*x[t], x[0] == 0.4}, x[t], t];

A very peculiar bug. It works if r is replaced by any of a, c, d, or e, but chokes for the other letters. What version and OS are you using, for reference? — J. M.'s missing motivation, May 14 '13 at 12:53
It seems that only variables that begin with a c d e will work (something like aaa is also OK)… very strange! — xzczd, May 14 '13 at 12:53
@J.M. I'm thinking about something to do with the lexicographical order of E — Dr. belisarius, May 14 '13 at 12:53
For what it's worth a lot of information is returned with Trace[. . ., TraceInternal -> True] for anyone who has the time and energy to dig through it. — Mr.Wizard, May 14 '13 at 13:06
@5xum Did you report this to support@wolfram.com as bug? Please do if you haven't yet and link back to this question. — Szabolcs, May 14 '13 at 17:13
@Szabolcs I reported it, will report when anything happens. It's CASE:134234 by the way — 5xum, May 16 '13 at 09:15
@5xum, is the ticket publically viewable? So we could track status change. — Nakilon, Jun 12 '13 at 16:25

Dr. belisarius · Accepted Answer · 2013-05-14T18:02:04.903

12

A little bit more. Still not fully diagnosed, but the problem isn't due to DSolve ... :

s1 = DSolve[{x'[t] == f*x[t] (1 - (x[t]/b)) - l x[t]}, x[t], t];
s2 = DSolve[{x'[t] == e*x[t] (1 - (x[t]/b)) - l x[t]}, x[t], t];

And the problem shows up when matching the initial condition:

Solve[(x[t] /. s2[[1]] /. t -> 0) == 4/10, C[1]]
(*
{{C[1] -> -(Log[1/2 (2 e - 5 b e + 5 b l)]/(b (e - l)))}}
*)

but

Solve[(x[t] /. s1[[1]] /. t -> 0) == 4/10, C[1]]

Solve::nsmet: This system cannot be solved with the methods available to Solve. >>

BTW,

Solve[(x[t] /. s1[[1]] /. t -> 0) == 4/10, C[1], Reals]

can be solved without any problem

Edit

I was able to track down the problem to:

Solve[E^(a w) (f - e) == E^(b w), {w}]

and

Solve[E^(a w) (f - g) == E^(b w), {w}]

only the first one gives a result!

edited May 14 '13 at 18:02

answered May 14 '13 at 13:06

Dr. belisarius

115,881
13
203
453

2

Wow. I was sure I was missing something completely obvious, but the chaotic behavior makes me think this is just a very bizzare bug... – 5xum May 14 '13 at 14:00
@5xum Not obvious at all ... – Dr. belisarius May 14 '13 at 14:03
cant solve this regardless of etters..Solve[E^(a w) (f - 1 ) == E^w, {w}] – george2079 May 14 '13 at 20:28
3

@5xum An apparent bug indeed, and one that has persisted at least from version 7 through version 9. I'm surprised this hasn't been found and addressed in that time. – Mr.Wizard May 15 '13 at 04:36
A more simplified one: Solve[E^(a w) (b - 1) == E^w, w]. – Silvia May 16 '13 at 03:47
@Silvia Sorry, changing which letter does it turn solvable? – Dr. belisarius May 16 '13 at 03:50
I can't find a setting which makes it work.. But I believe it's the some issue. btw I traced to a System`Private`OldSolve function.. – Silvia May 16 '13 at 04:08
@Silvia Oh, I see now. Thanks! – Dr. belisarius May 16 '13 at 04:10
3

I guess this is a plain bug, a pattern matching messup that makes MMA think it can solve one expression and not the other. It's funny how it can solve the last example only if at least one of the two variables you add or subtract is sorted before the letter E (or whatever you put as base to that power) – Rojo May 16 '13 at 16:58
2

@Silvia Try the Solve[] with MaxExtraConditions -> All – Dr. belisarius May 17 '13 at 01:24
Wow didn't know this option! Thanks! – Silvia May 17 '13 at 02:47
@5xum If we can narrow down the bug to a specific set of variables, then it would be nice if the accepted answer patches(well monkey patches the issue) the issue maybe using Replace – William Jun 13 '13 at 00:19

score 7 · Answer 2 · edited Apr 13 '17 at 12:55

7

The problem can be reduced to the DSolve expressions:

DSolve[{x'[t] == a*x[t]*(1 - (x[t]/b)) - l*x[t], x[0] == 0.4}, x[t], t]

DSolve[{x'[t] == h*x[t]*(1 - (x[t]/b)) - l*x[t], x[0] == 0.4}, x[t], t]

One can see that alphabetical order appears important:

With[{a = Symbol@#},
  Shallow @ DSolve[{x'[t] == a*x[t]*(1 - (x[t]/b)) - l*x[t], x[0] == 0.4}, x[t], t]
] & /@ DeleteCases[CharacterRange["a", "z"], "b" | "l" | "t" | "x"]

{{{Rule[<<2>>]}}, {{Rule[<<2>>]}}, {{Rule[<<2>>]}}, {{Rule[<<2>>]}}, {}, {}, {},
  {}, {}, {}, {}, {}, {}, {}, {}, {}, {}, {}, {}, {}, {}, {}}

I suspect that this may be related to: Why does Simplify ignore an assumption?
Unfortunately I cannot think of a robust way to address the problem.

edited Apr 13 '17 at 12:55

Community

1

answered May 14 '13 at 12:56

Mr.Wizard

271,378
34
587
1,371

Interesting. Definitely, interesting. – rcollyer May 14 '13 at 12:59
4

Finally I have a justifiable reason for using aardvark as a variable name :-) – Simon Woods May 14 '13 at 13:21
3

@SimonWoods You might then be interested in AAAAAAAAAAAAAAAAA! :D – rm -rf May 14 '13 at 13:35
@SimonWoods DSolve[{ax'[at] == ah*ax[at]*(1 - (ax[at]/ab)) - l*ax[at], ax[0] == 0.4}, ax[at], at] seems to work... – geordie May 14 '13 at 22:29
If you want to "address" the problem in a robust way (as opposed to "diagnosing" the cause of the bug), I think that SetOptions[Solve,MaxExtraConditions -> All] may help – Dr. belisarius May 17 '13 at 05:16
@belisarius I don't think that option is present in Version 7, unless undocumented. – Mr.Wizard May 17 '13 at 07:11
@Mr.Wizard It was introduced in 8 to cope with some V7 inconsistency http://forums.wolfram.com/student-support/topics/325718 – Dr. belisarius May 17 '13 at 12:19

Variable naming changes everything

2 Answers2

Linked