Any ideas on how to use the Region` context?

Question

If you type

?Region`*

you'll get:

Mathematica graphics

which seems a bunch of interesting and not documented symbols.

Any idea (or experience) on how to use them?

Edit

By using our "collective spelunking" I was able to work out this answer - Great! :)

And Silvia used it to write another one!

@cormullion Great! I was trying with parametrized regions. So the objects involved should be Geometric thingies. Let's try! — Dr. belisarius, Dec 20 '13 at 18:39
Region`RegionCentroid[Rectangle[{5, 5}, {25, 25}]] gives {15, 15} — cormullion, Dec 20 '13 at 18:39
@cormullion Region`ConvexRegionQ[Circle[]] hey Region`ConvexRegionQ[Disk[]] — Dr. belisarius, Dec 20 '13 at 18:42
Check this: Region`RegionProperty[Polygon[{{1, 0}, {0, 1}, {2, 3}}], {x, y}, "FastDescription"] — Simon Woods, Dec 20 '13 at 22:10
@SimonWoods Hey! That's great! Is there an inverse function for that? — Dr. belisarius, Dec 20 '13 at 22:11
@belisarius, it's in the definition for Region`BoundedParametrization — Simon Woods, Dec 20 '13 at 22:18
Great find by the way. I wish we could get documentation for some of the useful stuff in these hidden-away packages. — Simon Woods, Dec 20 '13 at 22:24
In Simon's footsteps, trying to find valid arguments for RegionProperty I ran Union@Cases[ ToExpression[#, InputForm, DownValues] & /@ Names["Region`*"], HoldPattern[Region`RegionProperty[__, s_String]] :> s, Infinity] to find {"Distance", "FastDescription", "ImplicitDescription", "Nearest", "SpaceDimension"}. SpecialRegionProperty can take {"Assumptions", "BoundingBox", "Centroid", "ConvexQ", "Distance", "ImplicitDescription", "InjectiveParametricDescription", "Instance", "Measure", "Nearest", "ParametricDescription", "RegionDimension", "SignedDistance", "SpaceDimension"} — Szabolcs, Dec 21 '13 at 00:12
If you dare wade through all of it, do this: 1. force-load all symbols using Symbol/@Names["Region`*"] 2. Mass-spelunk Scan[Spelunk, Names["Region`*"]] — Szabolcs, Dec 21 '13 at 00:17
I think the usage of the "Region`" functions is different in V10 -- anyone around with an RPi to check? — Michael E2, Dec 22 '13 at 00:35
@MichaelE2 There are some more functions; BallRegion, SimplexRegion are changed to Ball, Simplex; at least ParametricRegion works different (don't know how yet). — Silvia, Dec 22 '13 at 01:13
@Silvia Try ParametricRegion[{{x, y}, 0 < x < 1 && 0 < y < 2}, {x, y}] — Michael E2, Dec 22 '13 at 01:33
@MichaelE2 Hmm... Why they declare {x, y} twice :( And what about RegionConvert in Simon's answer? — Silvia, Dec 22 '13 at 01:38
@Silvia ParametricRegion[{{s, t}, -1 <= s <= 1 && -1 <= t <= 1, {s^2 t^2, s t^3}}] — Dr. belisarius, Jun 09 '14 at 17:57

score 16 · Accepted Answer · edited Apr 13 '17 at 12:55

For a more clear view, here is a table of some of the Region functions.

AppendTo[$ContextPath, "Region`"]

Clear[testfunc]
testfunc[reg_] := {ToString /@ #, Through[#[reg]]} &[{
                    ConvexRegionQ,
                    BoundedRegionQ,
                    RegionDimension,
                    Module[{dim = RegionEmbeddingDimension[#]},
                           var = Symbol["x" <> ToString[#]] & /@ Range[dim];
                           dim] &,
                    RegionMeasure,
                    RegionCentroid,
                    RegionProperty[#, var, "FastDescription"] &,
                    RegionProperty[#, var, "ImplicitDescription"] &,
                    RegionElement,
                    LevelFunction[RegionProperty[#, var, "FastDescription"][[1, 2]]] &
                  }] // 
          Grid[Insert[#, {ConvexRegionQ, BoundedRegionQ, RegionDimension, 
               RegionEmbeddingDimension, RegionMeasure, RegionCentroid, 
               FastDescription, ImplicitDescription, RegionElement, 
               LevelFunction}, 2]\[Transpose], Dividers -> All, 
            FrameStyle -> GrayLevel[.8], Alignment -> Left] & // Quiet

In addition of BoxRegion, other *Regions also seems to be used to declare regions:

Names["Region`*Region"]

{"BallRegion", "BooleanRegion", "BoxRegion", "EllipsoidRegion", "EmptyRegion", "FullRegion", "InverseTransformedRegion", "ParametricRegion", "SimplexRegion", "TransformedRegion"}

For example, a 2D triangle embeded in 7D space:

tri3d = RandomInteger[{-10, 10}, {3, 3}];
tri7d = ArrayFlatten[{{tri3d, ConstantArray[0, {3, 4}]}}];
(* a random rotate in 7D space: *)
rt7d = RotationTransform[{{0, 0, 1, 0, 0, 0, 0}, RandomInteger[{-1, 1}, 7]},
                         ConstantArray[0, 7]];
tri7d = rt7d /@ tri7d;
testfunc@SimplexRegion[tri7d]

test for 7D triangle

Maybe some of them (LevelFunction) work only on "full-rank" regions?

simplex = Function[dim, SimplexRegion[RandomInteger[{-10, 10}, {dim + 1, dim}]]] @ 4
testfunc @ simplex

test for simplex

Some regions look like special cases:

RegionDimension@EmptyRegion[2]

$-\infty$

RegionMeasure@FullRegion[3]

$\infty$

Edit:

SimplePolygonPartition can be used to divide self-intersecting Polygon to simple pieces. The usage is like

SimplePolygonPartition[Polygon[...]]
SimplePolygonPartition[Polygon[...],Graphics`Region`RegionDump`FillingMethod->"OddEvenRule"]

An example can be found here.

@belisarius The Uncomplete Unofficial Documentation for Undocumented Functions :P — Silvia, Dec 21 '13 at 04:02
take a look! http://mathematica.stackexchange.com/a/39206/193 — Dr. belisarius, Dec 21 '13 at 06:49
@belisarius Thanks for you and Simon's enlightenment, I found a similar solution :) — Silvia, Dec 22 '13 at 00:25
Yup, I found it while trying to answer that very question, but I couldn't make it work but for very small polygs. I forgot to document it here, sorry. Upvoted your linked answer :) — Dr. belisarius, Jan 28 '14 at 09:13
@Silvia, SimplePolygonPartition has appeared on the site before — Simon Woods, Jan 28 '14 at 09:33
@SimonWoods Great works! I'm having fun of Tracing those functions :) — Silvia, Jan 28 '14 at 09:48
@Silvia, have fun :-) I spend some time a while ago digging into Graphics`Mesh, learning how to work with MeshObjects. I found some quite cool stuff but then got fed up when I upgraded to version 9 and a lot of it no longer worked the same way. One of the perils of using undocmented functions I suppose. — Simon Woods, Jan 28 '14 at 10:05

score 13 · Answer 2 · edited Dec 21 '13 at 00:36

This is quite a find. I've only had time to play with it a little, but are some interesting results:

Region`ConvexRegionQ[Disk[{1., 0.}]]

True

Region`RegionCentroid[Disk[{1., 0.}]]

{1., 0.}

Region`RegionMeasure[Disk[{1., 0.}]]

π

Region`RegionIntersection[Disk[{0, 0}], Disk[{1, 0}]]

seems to do nothing, but

Region`RegionMeasure @ Region`RegionIntersection[Disk[{0, 0}], Disk[{1, 0}]]

-(Sqrt[3]/2) + (2 π)/3

It appears one can create regions and operate on them:

box = Region`BoxRegion[{0, 0}, {2, 3}];
Region`RegionMeasure @ box

Region`RegionCentroid @ box

{1, 3/2}

+1 And it seems most of them also work for 3D cases. – Silvia Dec 21 '13 at 00:11 — Silvia, Dec 21 '13 at 00:11

score 9 · Answer 3 · answered Dec 21 '13 at 21:59

Its interesting to note that the Region context is loaded when you evaluate Graphics`Region`RegionInit[]. Old favourite Graphics`Mesh gets loaded too. There is some interesting looking stuff in Graphics`Region, clearly incomplete, for example one of the definitions is this...

BoundingRegion[___] := "Implement me..."

I've not done much spelunking yet, but did find this:

Graphics`Region`RegionInit[];

RegionConvert[Disk[]]
(* MeshRegion[{2, 2}, {951, 2289, 1339}, <>] *)

Graphics[Line @ MeshCoordinates[%, 1]]

enter image description here

"Implement me..." There's some sentient code! – cormullion Dec 22 '13 at 00:02 — cormullion, Dec 22 '13 at 00:02

Dr. belisarius · Answer 4 · 2013-12-21T05:58:55.343

7

Four more:

RegionNearest[] returns the nearest point inside a region to a given point:

AppendTo[$ContextPath, "Region`"]

RegionNearest[Disk[], {3, 4}]
(*
 {3/5, 4/5}
*)

RegionDifference[] seems to return unevaluated ... but no:

RegionMeasure@RegionDifference[Rectangle[], Disk[]]
(*
 1 - π/4
*)

TransformedRegion[] also seems to return unevaluated ... but again:

RegionMeasure@TransformedRegion[Rectangle[], ScalingTransform[{3, 2}]]
(*
 6
*)

ParametricRegion[]:

RegionMeasure@ParametricRegion[{{x, y}, 0 < x < 1 && 0 < y < 2}]
(*
 2
*)

edited Dec 21 '13 at 05:58

answered Dec 21 '13 at 05:15

Dr. belisarius

115,881
13
203
453

@Silvia RegionMeasure@ParametricRegion[{{x, y}, 0 < x < 1 && 0 < y < 2}] – Dr. belisarius Dec 21 '13 at 05:58
Sorry I missed that.. But ParametricRegion will be my most interested one :) – Silvia Dec 21 '13 at 05:58
Wow! Brilliant! – Silvia Dec 21 '13 at 05:58

score 0 · Answer 5 · answered Sep 04 '23 at 09:46

So far as I know, the region properties can be:

In[1]:= Union[
 Join[Region`SpecialBoundaryProperty[]; 
  Cases[GeneralUtilities`Definitions[
    "SpecialBoundariesDump`SRBdryRule"], _String, -1], 
  Region`SpecialRegionProperty[]; 
  Cases[GeneralUtilities`Definitions[
    "SpecialRegionsDump`SRPropRule"], _String, \[Infinity]]]]
Out[1]= {"Assumptions", "Boundary", "BoundingBox", "Centroid", 

"ConvexQ", "Distance", "ImplicitDescription", 

"InjectiveParametricDescription", "Instance", "LinearGraphics", 

"Measure", "Nearest", "ParametricDescription", "Primitive", "Region", 

"RegionDimension", "SignedDistance", "SimpleBoundary", 

"SimplicialDecomposition", "SpaceDimension", "Type"}

Unfortunately, this list is incomplete. According to

In[2]:= Region`RegionProperty[Pyramid[],{x,y,z},"FastDescription"]
Out[2]= {{{x,y,z},-4 (-2-2 y+2 z)>=0&&-4 (-2+2 x+2 z)>=0&&-4 (-2+2 y+2 z)>=0&&4 (2+2 x-2 z)>=0&&16 z>=0}}
In[3]:= Region`RegionProperty[Pyramid[],{x,y,z},"FastImplicitDescription"]
Out[3]= -4 (-2-2 y+2 z)>=0&&-4 (-2+2 x+2 z)>=0&&-4 (-2+2 y+2 z)>=0&&4 (2+2 x-2 z)>=0&&16 z>=0
In[4]:= Region`RegionProperty[Pyramid[],{x,y,z},True,"ImplicitDescription"]
Out[4]= {(x==-1&&((y==-1&&z==0)||(-1<y<0&&z==0)||(y==0&&z==0)||(0<y<1&&z==0)||(y==1&&z==0)))||(-1<x<0&&((y==-1&&z==0)||(-1<y<x&&0<=z<=1+y)||(y==x&&0<=z<=1+y)||(x<y<0&&0<=z<=1+x)||(y==0&&0<=z<=1+x)||(0<y<-x&&0<=z<=1+x)||(y==-x&&0<=z<=1+x)||(-x<y<1&&0<=z<=1-y)||(y==1&&z==0)))||(x==0&&((y==-1&&z==0)||(-1<y<0&&0<=z<=1+y)||(y==0&&0<=z<=1-y)||(0<y<1&&0<=z<=1-y)||(y==1&&z==0)))||(0<x<1&&((y==-1&&z==0)||(-1<y<-x&&0<=z<=1+y)||(y==-x&&0<=z<=1+y)||(-x<y<0&&0<=z<=1-x)||(y==0&&0<=z<=1-x)||(0<y<x&&0<=z<=1-x)||(y==x&&0<=z<=1-y)||(x<y<1&&0<=z<=1-y)||(y==1&&z==0)))||(x==1&&((y==-1&&z==0)||(-1<y<0&&z==0)||(y==0&&z==0)||(0<y<1&&z==0)||(y==1&&z==0))),True}

"FastImplicitDescription" is also a valid region property.
So, is there a complete list?

Any ideas on how to use the Region` context?

5 Answers5

Edit:

Linked