Interdependent controls in Manipulate

Question

Possible Duplicate:
How to create interrelated sliders?
locking a value when manipulating variables

I need to create a Manipulate with two control parameters which are linked by some mathematical relationship. So the user can decide to use either control and when that control is changed, the other will change too.

The example below works as required, using If statements to determine if one of the parameters has been changed and setting the other parameter appropriately.

Although this code works, I suspect there is a better/neater approach which avoids the need to "manually" keep track of oldx and oldy. What is the best way to do it?

oldx = oldy = 0;
Manipulate[
If[x != oldx, y = 1/x; oldx = x];
If[y != oldy, x = 1/y; oldy = y];
{x, y},
{x, 0.1, 10}, {y, 0.1, 10}]

I am almost positive this question is a duplicate yet I cannot find it. Does this seem overly familiar to anyone else? — Mr.Wizard, May 10 '12 at 14:23
I suppose I was thinking of this: http://mathematica.stackexchange.com/q/1373/121 — Mr.Wizard, May 10 '12 at 14:25
@Mr.Wizard I would say this is similar to this one: http://mathematica.stackexchange.com/questions/4212/locking-a-value-when-manipulating-variables/ — FJRA, May 10 '12 at 14:36
Thanks for the links. I did search before I posted the question, but didn't come up with anything. — Simon Woods, May 11 '12 at 19:35

score 17 · Accepted Answer · edited Apr 29 '17 at 11:25

17

Not sure if this is the best way, but you could consider something like this:

Manipulate[
 {x, y},
 {x, Manipulator[Dynamic[x, (x = #; y = 1/#) &], {.1, 10}] &},
 {y, Manipulator[Dynamic[y, (y = #; x = 1/#) &], {.1, 10}] &},
 Initialization :> ({x, y} = {1, 1})]

Edit V10

Since V10 one can use a shorter form:

Manipulate[
    {x, y}
  , {x, .1, 10, TrackingFunction :> ((x = #; y = 1/#) &)}
  , {y, .1, 10, TrackingFunction :> ((y = #; x = 1/#) &)}
  , Initialization :> ({x, y} = {1, 1})
]

edited Apr 29 '17 at 11:25

Kuba

136,707
13
279
740

answered May 10 '12 at 14:15

Heike

35,858
3
108
157

Thanks Heike, this is exactly what I need. – Simon Woods May 11 '12 at 19:35

rm -rf · Answer 2 · 2016-07-01T23:33:03.923

9

You could also build a custom Manipulate-like object using sliders

Panel[DynamicModule[{x, y},
    Column[{
        Grid[{
            {"x", Slider[Dynamic[x, (x = #; y = 1/#) &], {0.1, 10}], Dynamic[x]},
            {"y", Slider[Dynamic[y, (y = #; x = 1/#) &], {0.1, 10}], Dynamic[y]}
        }],
        Panel[{Dynamic[x], Dynamic[y]}, ImageSize -> 300, Background -> White]
    }], ImageSize -> 300
]]

enter image description here

edited Jul 01 '16 at 23:33

answered May 10 '12 at 14:22

rm -rf

88,781
21
293
472

Did you want the 2nd ImageSize to be an option to outside Panel? – Michael E2 Jul 02 '16 at 02:43
@MichaelE2 Hmm, I guess that isn't necessary. I don't actually remember why I had it any more, heh. I was just correcting an accepted suggested edit that fixed a typo (missing ]) but was applied in the wrong place and messed up the formatting. – rm -rf Jul 02 '16 at 05:27

score 3 · Answer 3 · answered May 10 '12 at 21:21

3

This?

{Slider[Dynamic[x], {0.1, 10}], 
 Slider[Dynamic[1/ x, Set[x, 1/#] &], {0.1, 10}]}
Dynamic[x]

Mathematica graphics

answered May 10 '12 at 21:21

acl

19,834
3
66
91

Interdependent controls in Manipulate

3 Answers3

Edit V10

Linked

Related