You could simply use the function prism from my answer to How can this texture be inserted in the beginning and the end of cylinder?.
The advantage is that it also allows you to add textures (optionally), and has vertex normals built in so that the shape appears smooth. Here it is just for fun:
l = {{"Directional", Red, ImageScaled[{2, 2, 2}]},
{"Directional", Green, ImageScaled[{-2, 2, 2}]},
{"Directional", Blue, ImageScaled[{-2, -2, 2}]}};
Graphics3D[{EdgeForm[], FaceForm[Opacity[.5]], prism[area, 500]},
Boxed -> True, Axes -> True, Lighting -> l, SphericalRegion -> True]
I set the shape to have no edges, so as to emphasize the smoothness. But if you want to see the striations on the side walls, just omit EdgeForm[] above. The result will then be this:
Edit
The original version of the function prism determined vertex normals based on the assumption that the shape is really a cylinder, or at least convex. That doesn't give very good estimates of all the appropriate vertex normals in this case, so it prompted me to look for a more accurate way of determining a set of vertex normals that still do the job of smoothly interpolating between adjacent face normals.
Here is what I came up with:
prism[pts_List, h_] :=
Module[{bottoms, tops, surfacePoints, sidePoints, n},
surfacePoints =
Table[Map[PadRight[#, 3, height] &, pts], {height, {0, h}}];
{bottoms, tops} = {Most[#], Rest[#]} &@surfacePoints;
sidePoints =
Flatten[{bottoms, RotateLeft[bottoms, {0, 1}],
RotateLeft[tops, {0, 1}], tops}, {{2, 3}, {1}}];
n = Length[sidePoints];
MapThread[Polygon[#1,
VertexNormals -> #2,
VertexTextureCoordinates -> #3] &, {Join[sidePoints,
surfacePoints],
Join[normals[sidePoints],
Map[({0, 0, h/2}) &, surfacePoints, {2}]],
Join[Table[{{i/n, 0}, {(i + 1)/n, 0}, {(i + 1)/n, 1}, {i/n,
1}}, {i, 0, n - 1}], {#, #} &[Rescale[pts, {-h, h}/2]]]}]]
normals[s_] := Module[{faceN, faceLeft, faceRight},
faceN = Map[Cross @@ Differences[#[[1 ;; 3]]] &, s];
faceLeft = RotateLeft[faceN];
faceRight = RotateRight[faceN];
MapThread[{#1 + #2, #1 + #3, #1 + #3, #1 + #2} &, {faceN, faceRight,
faceLeft}]
]
Manipulate[
Graphics3D[{EdgeForm[], FaceForm[Opacity[.5]],
GeometricTransformation[prism[area, 500],
Composition[
RotationTransform[θ, {0, 0, 1}],
TranslationTransform[{-1000, -500, 0}]]]}, Boxed -> False,
Axes -> False, ImageSize -> 600, Lighting -> l,
PlotRange -> {{-1200, 1200}, {-1200, 1200}, {-10, 510}}], {θ,
0, 2 Pi}
]
In the VertexNormals option, prism now calls the function normals which takes a list of polygon face quads and calculates for each vertex what the normals of adjacent faces are. Then it just adds those normals as a way to produce an interpolating average that makes the side walls look smooth. For the top and bottom of the prism, I chose a constant vertical normal (it doesn't even change direction because that is taken care of by the fact that the polygon orientation is opposite on top and bottom).
Having a smooth side wall may or may not be what the question is after - but since this is the main point of my answer, I decided to expand on the discussion of VertexNormals for the sake of completeness.
ListCurvePathPlot. – Sjoerd C. de Vries Apr 29 '15 at 19:15