4

I want to mark critical areas for statistical test on the plot. How can I do this? This:

pdf = PDF[NormalDistribution[], x]
Show[Plot[pdf, {x, -5, 5}], 
 Plot[pdf, {x, -5, -2.001}, Filling -> Axis]]

gives:

enter image description here

I know that it is probably some super-duper Mathematica feature, but as far as I know this filling shouldn't be cut in such strange way, so I don't want to use this feature. How can I make the filling look right?

Mr.Wizard
  • 271,378
  • 34
  • 587
  • 1,371
Misery
  • 2,640
  • 1
  • 30
  • 39
  • Look at your second plot separately and you'll see it is cut too. Why should it be drawn completely when you combine the two graphs? Try PlotRange->All in your second graph which ensures that the whole curve is plotted. – halirutan May 14 '13 at 07:55
  • PlotRange->All does not work either. But it works very well for x in <-4,4>. Mathematica knows which numbers are inappropriate! And if it decided that {-5,5} is wrong, and should cut the plot, it is right :p – Misery May 14 '13 at 07:58
  • 3
    looking at @J.M.'s answer in http://mathematica.stackexchange.com/questions/18964/how-can-i-fill-under-a-function-in-a-plot-just-to-right-of-a-specified-vertical you could also do (avoiding show): With[{dist = PDF[NormalDistribution[], #] &}, Plot[{ConditionalExpression[dist[x], x < -2], dist[x]}, {x, -5, 5}, Filling -> {1 -> Axis}, PlotStyle -> ColorData[1, 1]]] – Pinguin Dirk May 14 '13 at 07:59
  • 3
    You have to use PlotRange->All inside your second plot, not in the Show. – halirutan May 14 '13 at 08:06
  • Thanks. But still Mathematica takes my breath away. It even knows that when I want to plot something, it inteligently assumes that i don't want to plot it in the whole. Wow! ;) – Misery May 14 '13 at 08:09
  • @Misery That's a convenience feature. Compare Plot[1/x, {x, 0, 2}] with Plot[1/x, {x, 0, 2}, PlotRange -> All]. If PlotRange -> All were the default people would surely complain about this example I gave. It is the default, so people complain about other examples. We can't eat the cake and have it too ;-) – Szabolcs May 14 '13 at 17:09

4 Answers4

7

The reason this isn't working is because the Plot where you have the fill only plots up to a y-value of around 0.03 (try it on its own, without the second plot which shows the whole range) which means that you don't have a fill all the way to the top of where it appears in the graph. You can correct this by forcing it to plot to a higher value of y using the PlotRange option. You can either specify exactly the PlotRange you want, or simply give it the option All.

pdf = PDF[NormalDistribution[], x]
Show[Plot[pdf, {x, -5, 5}],Plot[pdf, {x, -5, -2.001}, Filling -> Axis, 
PlotRange -> All]]

enter image description here

Note that where you put the PlotRange option is important. If you don't include it in the filled graphic then that graphic will be evaluated in the standard way and thus won't include the information for the filling up to the point you want. If you include the PlotRange option as an option in Show, or as an option in the first plot then it will not effect the information coming from the filled plot.

In general the non-default options for Show are taken from the graphics elements from the first one on. If the first element has PlotRange->{0,3} and the second has PlotRange->{0,4}, then the option for the whole graphics object will be PlotRange->{0,3}. It is worth playing with the different values for the PlotRanges in the following to see what is happening:

Show[Plot[x^2, {x, 0, 5}, PlotRange -> {0, 4}],Plot[x^3, {x, 0, 5}, PlotRange -> {0, 3}], PlotRange -> {0, 5}]

This particular set of options will give you the following plot but if you alter the values in PlotRange above, you will see how Show is taking these options. Try also without the final PlotRange to see which option it takes and how the graph looks:

examples of plotrange options

Jonathan Shock
  • 3,015
  • 15
  • 24
  • Without explaining why it works now, the answer is useless for inexperienced users of Mathematica. If you don't know the reason for sure, only the fix, then give it a shot. You probably get corrected by the community, but you definitely learned something yourself. – halirutan May 14 '13 at 07:52
  • No! It is very useful! Mathematica just has so many features, and is so inteligent... and so on. According to the saying: "It's not a bug! It's a feature". I learned its philosophy by heart and now I am happy that I spent so much money for this... ekhm miracle of software engineering! – Misery May 14 '13 at 07:56
  • 1
    using this approach, you better Clear@x before defining pdf (or use pdf := PDF[NormalDistribution[], #] & and then pdf[x] in the plots) (or is there an easier way?) – Pinguin Dirk May 14 '13 at 08:03
  • 1
    @Misery I was referring to other users finding this question and hoping for an explanation of the behavior. Assume a slightly more difficult problem and having a more complex solution without any explanation. – halirutan May 14 '13 at 08:06
  • It was in new session of Mathematica so x didn't exist. But it is a vital suggestion. Thanks. – Misery May 14 '13 at 08:06
  • @halirutan: I know. But I am soooo disappointed with Mathematica and it's philosophy "It's not a bug, it's a feature" that I don't expect any good explanation exists. But You're absolutely right. Hope I didn't upset you. – Misery May 14 '13 at 08:12
  • @halirutan, my apologies, you are right. This was not a very useful answer. I'll add some notes as to what's going on. – Jonathan Shock May 14 '13 at 09:02
  • @halirutan There are many comments (useful or not), explanations why each answer works. Also statement that separate second plot is cut, so it will be cut in Show is not very helpful for beginners because what is missing is Why the second plot is cut. That is strange for beginners. Well, I'd love to see good explanation. – Kuba May 14 '13 at 09:06
  • @Kuba The simple explanation is that Show uses the options of the first argument, so sometimes the second one can get truncated if you don't pass the right options. – rm -rf May 14 '13 at 23:54
  • @rm-rf First plot contains area truncated in second at the end so I do not understand Your explanation. Moreover, separate second plot is truncated, that's my point, that's the "feature" which is strange for beginners. I still do not know why it is so. – Kuba May 15 '13 at 00:18
  • @Kuba, this is because within the Show, the information from the filled plot simply isn't there if you don't have the PlotRange option in it. Compare: Show[Plot[pdf, {x, -5, -2.001}, Filling -> Axis], PlotRange -> All] with Show[Plot[pdf, {x, -5, -2.001}, Filling -> Axis,PlotRange -> All]]. The list of non-default options from the graphics elements are concatenated in the Show command but if there are multiple possibilities for the same option then it will use the first one that shows up in the elements being displayed. – Jonathan Shock May 15 '13 at 00:39
  • @Kuba I'll admit it might be a bit strange for a beginner, but it's documented. The plotting functions try to show the region that is "most interesting" (or the range where most of the y values are). For example, try this: Plot[Sinc[x] - Piecewise[{{Sin[x]/x, Abs[x] < 2}}, 1], {x, -2.01, 2}] with and without PlotRange -> All. It is up to the user to verify and modify according to their needs. Since each person's definition of "interesting" varies, I think this compromise is reasonable. Of course, those advocating for explicit options have nothing to lose, since you can still be explicit. – rm -rf May 15 '13 at 00:44
  • @Kuba, I've added an explanation to the answer which shows a little more about how PlotRange can be used in Show. – Jonathan Shock May 15 '13 at 00:46
7

Putting Pinguin Dirk's comment into an answer:

With[{dist = PDF[NormalDistribution[]]}, 
 Plot[{If[x < -2, dist[x]], dist[x]}, {x, -5, 5},
  Filling -> {1 -> Axis}, 
  PlotStyle -> ColorData[1, 1]
 ]
]

Observe that ConditionalExpression is not needed as a simple and concise If is sufficient, and If also works in version 7 which the former does not.

Regarding your sarcastic comment:

But still Mathematica takes my breath away. It even knows that when I want to plot something, it inteligently(sic) assumes that i don't want to plot it in the whole. Wow! ;)

If you do not like the narrowed range you can use PlotRange -> Full to show the full plot range even if it is empty space. You can also use SetOptions to make this setting the default for one or more functions.

Community
  • 1
Mr.Wizard
  • 271,378
  • 34
  • 587
  • 1,371
4

Here is another solution. The idea is constructing another function (Piecewise[{{0, x <= -2}}, pdf]) for pdf to fill, then you can fill the plot in a common style.

pdf = PDF[NormalDistribution[], x];
Plot[{pdf, Piecewise[{{0, x <= -2}}, pdf]}, {x, -5, 5}, Filling -> {1 -> {2}}]
luyuwuli
  • 2,814
  • 19
  • 25
3

Another method:

With[{pdf = PDF[NormalDistribution[]], cv = -2.001},
 ParametricPlot[{x, t pdf[x]}, {x, -5, 5}, {t, 0, 1}, 
  MeshFunctions -> {#3 &}, Mesh -> {{cv}}, 
  MeshShading -> {Directive[Opacity[0.2], ColorData[1][1]], None}, 
  AspectRatio -> 1/GoldenRatio, PlotRange -> All, Frame -> False]
 ]

ParametricPlot output

Two-tailed:

With[{pdf = PDF[NormalDistribution[]], cv = 2.001},
 ParametricPlot[{x, t pdf[x]}, {x, -5, 5}, {t, 0, 1}, 
  MeshFunctions -> {#3 &}, Mesh -> {{-cv, cv}}, 
  MeshShading -> {Directive[Opacity[0.2], ColorData[1][1]], None}, 
  AspectRatio -> 1/GoldenRatio, PlotRange -> All, Frame -> False]
 ]

Right-tailed (note the reversal of MeshShading):

With[{pdf = PDF[NormalDistribution[]], cv = 2.001},
 ParametricPlot[{x, t pdf[x]}, {x, -5, 5}, {t, 0, 1}, 
  MeshFunctions -> {#3 &}, Mesh -> {{cv}}, 
  MeshShading -> {None, Directive[Opacity[0.2], ColorData[1][1]]}, 
  AspectRatio -> 1/GoldenRatio, PlotRange -> All, Frame -> False]
 ]
Michael E2
  • 235,386
  • 17
  • 334
  • 747