Plotting in polar coordinates, simple implicit curves

Question

How can I plot $\theta=\cos r$ in polar plane? Of course I know that it is different from $r=\cos \theta.$

ContourPlot[θ == Cos[r], {r, 0, 50}, {θ, -π, π}, MaxRecursion -> 2, PlotPoints -> 50, PlotRange -> All, AspectRatio -> Automatic, DisplayFunction -> ReplaceAll[{r_Real, t_Real} :> {r*Cos[t], r*Sin[t]}]] https://mathematica.stackexchange.com/a/300018/72111 — cvgmt, Mar 06 '24 at 10:48

Kuba · Answer 1 · 2017-06-14T08:43:45.193

If you can transform it to a parametric form:

ParametricPlot[
  Evaluate @ CoordinateTransform["Polar" -> "Cartesian", {r, Cos[r]}], 
  {r, 0, 50}
]

enter image description here

And if you have to use implicit form:

ContourPlot[
    Evaluate[
        TransformedField[
            "Polar" -> "Cartesian", θ == Cos[r], {r, θ} -> {x, y}
        ] 
    ]
  , {x, 0, 50}
  , {y, -50, 50}
  , PlotPoints -> 25
  , AspectRatio -> Automatic
  , Frame -> False, Axes -> True
 ]

Basheer Algohi · Answer 2 · 2014-12-04T08:26:36.980

7

Does this work for you:

PolarPlot[{ArcCos[t], -ArcCos[t]}, {t, -1,1}]

enter image description here

Update: (Sjoerd C. de Vries comment)

For all r

r=(+/-)ArcCos[t]+2 n Pi

Taking few of r results:

Show[Table[
  PolarPlot[{ArcCos[t], -ArcCos[t]} + n 2 Pi, {t, -1, 1}, 
   PlotRange -> All], {n, -10, 10}]]

enter image description here

edited Dec 04 '14 at 08:26

answered Dec 04 '14 at 05:21

Basheer Algohi

19,917
1
31
78

Let $\theta$ is arbitrary, How is the graph? – Nimbigli Dec 04 '14 at 05:45
I don't understand you. but in general for each theta you will find r using ArcCos[theta]. then {theta,r} will be a point in the plot. – Basheer Algohi Dec 04 '14 at 05:52
2

I suppose you should take into account that r is unrestricted, so you have to work with Mod 2 pi. – Sjoerd C. de Vries Dec 04 '14 at 07:28
Why is left side included? theta is Cos[r] so in <-1,1> interval, right? – Kuba Dec 04 '14 at 09:40
for each theta we can have r and -r. check this: Reduce[theta == Cos[r], r]. – Basheer Algohi Dec 04 '14 at 09:46
1

That's probably kind of academic discussion but there is Cos[r] and r is > 0, if you assume that r can be negative, then ok. – Kuba Dec 04 '14 at 09:54

xzczd · Answer 3 · 2019-08-18T04:57:13.990

Another possible solution is to

ContourPlot the equation directly;
Make the coordinate transform on the coordinates of points inside the resulting graphic.

I've wrapped these steps in a function:

ClearAll@implicitPlot
implicitPlot[eq_, range__, coordSys_, opt : OptionsPattern[ContourPlot]] := 
 Module[{coord}, 
  With[{plot = ContourPlot[eq, range, opt, PlotRange -> All], 
    trans = #[coord, #2] &[Function, 
       CoordinateTransform[coordSys -> "Cartesian", {coord[1], coord[2]}]] /. 
      coord[i_] :> Part[coord, i]}, 
   plot /. GraphicsComplex[coord_, rest_] :> 
     GraphicsComplex[trans[coord\[Transpose]]\[Transpose], rest]]]

implicitPlot[Cos@r == theta, {r, 0, 40}, {theta, -8 Pi, 8 Pi}, "Polar", 
 PlotPoints -> 100]

Mathematica graphics

The advantage of this approach is, it allows us to directly set domain of definition under the interested coordinate system.

george2079 · Answer 4 · 2017-06-14T01:21:32.267

3

for completeness this can be done with ContourPlot (solutions already given are faster and probably better quality)

ContourPlot[
 Cos[Norm[{x, y}]] - ArcTan[x, y] == 0, {x, 0, 100}, {y, -100, 100}, 
 PlotPoints -> 100]

edited Jun 14 '17 at 01:21

answered Jun 13 '17 at 21:22

george2079

38,913
1
43
110

Plotting in polar coordinates, simple implicit curves

4 Answers4

Linked